51 lines
1.7 KiB
Nix
51 lines
1.7 KiB
Nix
{ buildGoModule, fetchFromGitHub, lib, installShellFiles }:
|
|
|
|
buildGoModule rec {
|
|
pname = "lf";
|
|
version = "15";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "gokcehan";
|
|
repo = "lf";
|
|
rev = "r${version}";
|
|
sha256 = "1fjwkng6fnbl6dlicbxj0z92hl9xggni5zfi3nsxn3fa6rmzbiay";
|
|
};
|
|
|
|
vendorSha256 = "10na3jzvln353ygcvbhj4243yr83skw5zf3r2n8p6d7i83i86c8w";
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
# TODO: Setting buildFlags probably isn't working properly. I've tried a few
|
|
# variants, e.g.:
|
|
# - buildFlags = [ "-ldflags" "\"-s" "-w"" ""-X 'main.gVersion=${version}'\"" ];
|
|
# - buildFlags = [ "-ldflags" "\\\"-X" "${goPackagePath}/main.gVersion=${version}\\\"" ];
|
|
# Override the build phase (to set buildFlags):
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
runHook renameImports
|
|
go install -ldflags="-s -w -X main.gVersion=r${version}"
|
|
runHook postBuild
|
|
'';
|
|
|
|
postInstall = ''
|
|
install -D --mode=444 lf.desktop $out/share/applications/lf.desktop
|
|
installManPage lf.1
|
|
installShellCompletion etc/lf.{zsh,fish}
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "A terminal file manager written in Go and heavily inspired by ranger";
|
|
longDescription = ''
|
|
lf (as in "list files") is a terminal file manager written in Go. It is
|
|
heavily inspired by ranger with some missing and extra features. Some of
|
|
the missing features are deliberately omitted since it is better if they
|
|
are handled by external tools.
|
|
'';
|
|
homepage = "https://godoc.org/github.com/gokcehan/lf";
|
|
changelog = "https://github.com/gokcehan/lf/releases/tag/r${version}";
|
|
license = licenses.mit;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ primeos ];
|
|
};
|
|
}
|