336bc8283b
This reverts commit c778945806.
I believe this is exactly what brings the staging branch into
the right shape after the last merge from master (through staging-next);
otherwise part of staging changes would be lost
(due to being already reachable from master but reverted).
54 lines
1.9 KiB
Nix
54 lines
1.9 KiB
Nix
{ lib, stdenv, fetch, cmake, python3, libcxxabi, fixDarwinDylibNames, version
|
|
, enableShared ? true }:
|
|
|
|
stdenv.mkDerivation {
|
|
pname = "libc++";
|
|
inherit version;
|
|
|
|
src = fetch "libcxx" "0v78bfr6h2zifvdqnj2wlfk4pvxzrqn3hg1v6lqk3y12bx9p9xny";
|
|
|
|
postUnpack = ''
|
|
unpackFile ${libcxxabi.src}
|
|
export LIBCXXABI_INCLUDE_DIR="$PWD/$(ls -d libcxxabi-${version}*)/include"
|
|
'';
|
|
|
|
patches = stdenv.lib.optional stdenv.hostPlatform.isMusl ../../libcxx-0001-musl-hacks.patch;
|
|
|
|
preConfigure = ''
|
|
# Get headers from the cxxabi source so we can see private headers not installed by the cxxabi package
|
|
cmakeFlagsArray=($cmakeFlagsArray -DLIBCXX_CXX_ABI_INCLUDE_PATHS="$LIBCXXABI_INCLUDE_DIR")
|
|
'' + lib.optionalString stdenv.hostPlatform.isMusl ''
|
|
patchShebangs utils/cat_files.py
|
|
'';
|
|
nativeBuildInputs = [ cmake ]
|
|
++ stdenv.lib.optional (stdenv.hostPlatform.isMusl || stdenv.hostPlatform.isWasi) python3
|
|
++ stdenv.lib.optional stdenv.hostPlatform.isDarwin fixDarwinDylibNames;
|
|
|
|
buildInputs = [ libcxxabi ];
|
|
|
|
cmakeFlags = [
|
|
"-DLIBCXX_LIBCXXABI_LIB_PATH=${libcxxabi}/lib"
|
|
"-DLIBCXX_LIBCPPABI_VERSION=2"
|
|
"-DLIBCXX_CXX_ABI=libcxxabi"
|
|
] ++ stdenv.lib.optional (stdenv.hostPlatform.isMusl || stdenv.hostPlatform.isWasi) "-DLIBCXX_HAS_MUSL_LIBC=1"
|
|
++ stdenv.lib.optional (stdenv.hostPlatform.useLLVM or false) "-DLIBCXX_USE_COMPILER_RT=ON"
|
|
++ stdenv.lib.optional stdenv.hostPlatform.isWasm [
|
|
"-DLIBCXX_ENABLE_THREADS=OFF"
|
|
"-DLIBCXX_ENABLE_FILESYSTEM=OFF"
|
|
"-DLIBCXX_ENABLE_EXCEPTIONS=OFF"
|
|
] ++ stdenv.lib.optional (!enableShared) "-DLIBCXX_ENABLE_SHARED=OFF";
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
passthru = {
|
|
isLLVM = true;
|
|
};
|
|
|
|
meta = {
|
|
homepage = "https://libcxx.llvm.org/";
|
|
description = "A new implementation of the C++ standard library, targeting C++11";
|
|
license = with stdenv.lib.licenses; [ ncsa mit ];
|
|
platforms = stdenv.lib.platforms.all;
|
|
};
|
|
}
|