4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
45 lines
1.2 KiB
Nix
45 lines
1.2 KiB
Nix
{ lib, stdenv, buildPackages, kernel, pciutils, gettext }:
|
|
|
|
stdenv.mkDerivation {
|
|
pname = "cpupower";
|
|
inherit (kernel) version src;
|
|
|
|
nativeBuildInputs = [ gettext ];
|
|
buildInputs = [ pciutils ];
|
|
|
|
postPatch = ''
|
|
cd tools/power/cpupower
|
|
sed -i 's,/bin/true,${buildPackages.coreutils}/bin/true,' Makefile
|
|
sed -i 's,/bin/pwd,${buildPackages.coreutils}/bin/pwd,' Makefile
|
|
sed -i 's,/usr/bin/install,${buildPackages.coreutils}/bin/install,' Makefile
|
|
'';
|
|
|
|
makeFlags = [
|
|
"CROSS=${stdenv.cc.targetPrefix}"
|
|
"CC=${stdenv.cc.targetPrefix}cc"
|
|
"LD=${stdenv.cc.targetPrefix}cc"
|
|
];
|
|
|
|
installFlags = stdenv.lib.mapAttrsToList
|
|
(n: v: "${n}dir=${placeholder "out"}/${v}") {
|
|
bin = "bin";
|
|
sbin = "sbin";
|
|
man = "share/man";
|
|
include = "include";
|
|
lib = "lib";
|
|
locale = "share/locale";
|
|
doc = "share/doc/cpupower";
|
|
conf = "etc";
|
|
bash_completion_ = "share/bash-completion/completions";
|
|
};
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with lib; {
|
|
description = "Tool to examine and tune power saving features";
|
|
homepage = "https://www.kernel.org/";
|
|
license = licenses.gpl2;
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|