4183604207
Darwin disallows shebang scripts from using other scripts as their command--the command must be a binary. This commit changes the `mix` shebang script from calling `elixir` directly (another shebang script), instead using `env` as an intermediary. Fixes #9050
58 lines
1.7 KiB
Nix
58 lines
1.7 KiB
Nix
{ stdenv, fetchurl, erlang, rebar, makeWrapper, coreutils, curl, bash }:
|
|
|
|
let
|
|
version = "1.0.5";
|
|
in
|
|
stdenv.mkDerivation {
|
|
name = "elixir-${version}";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/elixir-lang/elixir/archive/v${version}.tar.gz";
|
|
sha256 = "1f419pzlcgqx68rygwwyp2hzh4vgp0avjydd84dpa7finckc5raw";
|
|
};
|
|
|
|
buildInputs = [ erlang rebar makeWrapper ];
|
|
|
|
preBuild = ''
|
|
# The build process uses ./rebar. Link it to the nixpkgs rebar
|
|
rm -v rebar
|
|
ln -s ${rebar}/bin/rebar rebar
|
|
|
|
substituteInPlace Makefile \
|
|
--replace "/usr/local" $out
|
|
'';
|
|
|
|
postFixup = ''
|
|
# Elixir binaries are shell scripts which run erl. Add some stuff
|
|
# to PATH so the scripts can run without problems.
|
|
|
|
for f in $out/bin/*; do
|
|
b=$(basename $f)
|
|
if [ $b == "mix" ]; then continue; fi
|
|
wrapProgram $f \
|
|
--prefix PATH ":" "${erlang}/bin:${coreutils}/bin:${curl}/bin:${bash}/bin" \
|
|
--set CURL_CA_BUNDLE /etc/ssl/certs/ca-certificates.crt
|
|
done
|
|
|
|
substituteInPlace $out/bin/mix \
|
|
--replace "/usr/bin/env elixir" "${coreutils}/bin/env $out/bin/elixir"
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = "http://elixir-lang.org/";
|
|
description = "A functional, meta-programming aware language built on top of the Erlang VM";
|
|
|
|
longDescription = ''
|
|
Elixir is a functional, meta-programming aware language built on
|
|
top of the Erlang VM. It is a dynamic language with flexible
|
|
syntax and macro support that leverages Erlang's abilities to
|
|
build concurrent, distributed and fault-tolerant applications
|
|
with hot code upgrades.
|
|
'';
|
|
|
|
license = licenses.epl10;
|
|
platforms = platforms.unix;
|
|
maintainers = [ maintainers.the-kenny ];
|
|
};
|
|
}
|