4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
43 lines
1.2 KiB
Nix
43 lines
1.2 KiB
Nix
{ lib, stdenv, fetchFromGitLab, kernel }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "ddcci-driver";
|
|
version = "0.3.3";
|
|
name = "${pname}-${kernel.version}-${version}";
|
|
|
|
src = fetchFromGitLab {
|
|
owner = "${pname}-linux";
|
|
repo = "${pname}-linux";
|
|
rev = "v${version}";
|
|
sha256 = "0vkkja3ykjil783zjpwp0vz7jy2fp9ccazzi3afd4fjk8gldin7f";
|
|
};
|
|
|
|
hardeningDisable = [ "pic" ];
|
|
|
|
nativeBuildInputs = kernel.moduleBuildDependencies;
|
|
|
|
prePatch = ''
|
|
substituteInPlace ./ddcci/Makefile \
|
|
--replace '"$(src)"' '$(PWD)' \
|
|
--replace depmod \#
|
|
substituteInPlace ./ddcci-backlight/Makefile \
|
|
--replace '"$(src)"' '$(PWD)' \
|
|
--replace depmod \#
|
|
'';
|
|
|
|
makeFlags = [
|
|
"KDIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
|
|
"KVER=${kernel.modDirVersion}"
|
|
"KERNEL_MODLIB=$(out)/lib/modules/${kernel.modDirVersion}"
|
|
"INCLUDEDIR=$(out)/include"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Kernel module driver for DDC/CI monitors";
|
|
homepage = "https://gitlab.com/ddcci-driver-linux/ddcci-driver-linux";
|
|
license = licenses.gpl2;
|
|
maintainers = with maintainers; [ bricewge ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|