0e5c971af8
Currently minio logs with enhanced tty data and journalctl does not include anything useful as a result:
```
Jun 08 11:03:28 alpha minio[17813]: [78B blob data]
Jun 08 11:03:28 alpha minio[17813]: [49B blob data]
Jun 08 11:03:28 alpha minio[17813]: [19B blob data]
Jun 08 11:03:28 alpha minio[17813]: [88B blob data]
Jun 08 11:03:28 alpha minio[17813]: [45B blob data]
Jun 08 11:03:28 alpha minio[17813]: [44B blob data]
Jun 08 11:03:28 alpha minio[17813]: [57B blob data]
```
Indicating that it detected some binary output. With the `--json` flag it logs:
```
Jun 08 11:14:58 alpha minio[18573]: {"level":"FATAL","time":"2018-06-07T23:14:58.770637778Z","error":{"message":"--address input is invalid: address 127.0.0.1: missing port in address","source":["/build/go/src/github.com/minio/minio/cmd/server-main.go:121:cmd.serverHandleCmdArgs()"]}}
```
112 lines
3.2 KiB
Nix
112 lines
3.2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.minio;
|
|
in
|
|
{
|
|
meta.maintainers = [ maintainers.bachp ];
|
|
|
|
options.services.minio = {
|
|
enable = mkEnableOption "Minio Object Storage";
|
|
|
|
listenAddress = mkOption {
|
|
default = ":9000";
|
|
type = types.str;
|
|
description = "Listen on a specific IP address and port.";
|
|
};
|
|
|
|
dataDir = mkOption {
|
|
default = "/var/lib/minio/data";
|
|
type = types.path;
|
|
description = "The data directory, for storing the objects.";
|
|
};
|
|
|
|
configDir = mkOption {
|
|
default = "/var/lib/minio/config";
|
|
type = types.path;
|
|
description = "The config directory, for the access keys and other settings.";
|
|
};
|
|
|
|
accessKey = mkOption {
|
|
default = "";
|
|
type = types.str;
|
|
description = ''
|
|
Access key of 5 to 20 characters in length that clients use to access the server.
|
|
This overrides the access key that is generated by minio on first startup and stored inside the
|
|
<literal>configDir</literal> directory.
|
|
'';
|
|
};
|
|
|
|
secretKey = mkOption {
|
|
default = "";
|
|
type = types.str;
|
|
description = ''
|
|
Specify the Secret key of 8 to 40 characters in length that clients use to access the server.
|
|
This overrides the secret key that is generated by minio on first startup and stored inside the
|
|
<literal>configDir</literal> directory.
|
|
'';
|
|
};
|
|
|
|
region = mkOption {
|
|
default = "us-east-1";
|
|
type = types.str;
|
|
description = ''
|
|
The physical location of the server. By default it is set to us-east-1, which is same as AWS S3's and Minio's default region.
|
|
'';
|
|
};
|
|
|
|
browser = mkOption {
|
|
default = true;
|
|
type = types.bool;
|
|
description = "Enable or disable access to web UI.";
|
|
};
|
|
|
|
package = mkOption {
|
|
default = pkgs.minio;
|
|
defaultText = "pkgs.minio";
|
|
type = types.package;
|
|
description = "Minio package to use.";
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
systemd.services.minio = {
|
|
description = "Minio Object Storage";
|
|
after = [ "network.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
preStart = ''
|
|
# Make sure directories exist with correct owner
|
|
mkdir -p ${cfg.configDir}
|
|
chown -R minio:minio ${cfg.configDir}
|
|
mkdir -p ${cfg.dataDir}
|
|
chown minio:minio ${cfg.dataDir}
|
|
'';
|
|
serviceConfig = {
|
|
PermissionsStartOnly = true;
|
|
ExecStart = "${cfg.package}/bin/minio server --json --address ${cfg.listenAddress} --config-dir=${cfg.configDir} ${cfg.dataDir}";
|
|
Type = "simple";
|
|
User = "minio";
|
|
Group = "minio";
|
|
LimitNOFILE = 65536;
|
|
};
|
|
environment = {
|
|
MINIO_REGION = "${cfg.region}";
|
|
MINIO_BROWSER = "${if cfg.browser then "on" else "off"}";
|
|
} // optionalAttrs (cfg.accessKey != "") {
|
|
MINIO_ACCESS_KEY = "${cfg.accessKey}";
|
|
} // optionalAttrs (cfg.secretKey != "") {
|
|
MINIO_SECRET_KEY = "${cfg.secretKey}";
|
|
};
|
|
};
|
|
|
|
users.extraUsers.minio = {
|
|
group = "minio";
|
|
uid = config.ids.uids.minio;
|
|
};
|
|
|
|
users.extraGroups.minio.gid = config.ids.uids.minio;
|
|
};
|
|
}
|