6b91b0d09f
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/chromedriver/versions. These checks were done: - built on NixOS - ran ‘/nix/store/bnjr4qgd68lh8fdz2hxz7qrc1zvvxkni-chromedriver-2.38/bin/chromedriver -h’ got 0 exit code - ran ‘/nix/store/bnjr4qgd68lh8fdz2hxz7qrc1zvvxkni-chromedriver-2.38/bin/chromedriver --help’ got 0 exit code - found 2.38 with grep in /nix/store/bnjr4qgd68lh8fdz2hxz7qrc1zvvxkni-chromedriver-2.38 - directory tree listing: https://gist.github.com/8ba491f60826e1ad2389e69f92fb6116
57 lines
1.6 KiB
Nix
57 lines
1.6 KiB
Nix
{ stdenv, fetchurl, cairo, fontconfig, freetype, gdk_pixbuf, glib
|
|
, glibc, gtk2, libX11, makeWrapper, nspr, nss, pango, unzip, gconf
|
|
, libXi, libXrender, libXext
|
|
}:
|
|
let
|
|
allSpecs = {
|
|
"x86_64-linux" = {
|
|
system = "linux64";
|
|
sha256 = "1h7avlns00hd44ayi53lvdj2l85h9higky0jk7bad07hm39nagks";
|
|
};
|
|
|
|
"x86_64-darwin" = {
|
|
system = "mac64";
|
|
sha256 = "11hs4mmlvxjaanq41h0dljj4sff0lfwk31svvdmzfg91idlikpsz";
|
|
};
|
|
};
|
|
|
|
spec = allSpecs."${stdenv.system}"
|
|
or (throw "missing chromedriver binary for ${stdenv.system}");
|
|
|
|
libs = stdenv.lib.makeLibraryPath [
|
|
stdenv.cc.cc.lib
|
|
cairo fontconfig freetype
|
|
gdk_pixbuf glib gtk2 gconf
|
|
libX11 nspr nss pango libXrender
|
|
gconf libXext libXi
|
|
];
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
name = "chromedriver-${version}";
|
|
version = "2.38";
|
|
|
|
src = fetchurl {
|
|
url = "http://chromedriver.storage.googleapis.com/${version}/chromedriver_${spec.system}.zip";
|
|
sha256 = spec.sha256;
|
|
};
|
|
|
|
nativeBuildInputs = [ unzip makeWrapper ];
|
|
|
|
unpackPhase = "unzip $src";
|
|
|
|
installPhase = ''
|
|
install -m755 -D chromedriver $out/bin/chromedriver
|
|
'' + stdenv.lib.optionalString (!stdenv.isDarwin) ''
|
|
patchelf --set-interpreter ${glibc.out}/lib/ld-linux-x86-64.so.2 $out/bin/chromedriver
|
|
wrapProgram "$out/bin/chromedriver" --prefix LD_LIBRARY_PATH : "${libs}:\$LD_LIBRARY_PATH"
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://sites.google.com/a/chromium.org/chromedriver;
|
|
description = "A WebDriver server for running Selenium tests on Chrome";
|
|
license = licenses.bsd3;
|
|
maintainers = [ maintainers.goibhniu ];
|
|
platforms = attrNames allSpecs;
|
|
};
|
|
}
|