c9baba9212
(My OCD kicked in today...) Remove repeated package names, capitalize first word, remove trailing periods and move overlong descriptions to longDescription. I also simplified some descriptions as well, when they were particularly long or technical, often based on Arch Linux' package descriptions. I've tried to stay away from generated expressions (and I think I succeeded). Some specifics worth mentioning: * cron, has "Vixie Cron" in its description. The "Vixie" part is not mentioned anywhere else. I kept it in a parenthesis at the end of the description. * ctags description started with "Exuberant Ctags ...", and the "exuberant" part is not mentioned elsewhere. Kept it in a parenthesis at the end of description. * nix has the description "The Nix Deployment System". Since that doesn't really say much what it is/does (especially after removing the package name!), I changed that to "Powerful package manager that makes package management reliable and reproducible" (borrowed from nixos.org). * Tons of "GNU Foo, Foo is a [the important bits]" descriptions is changed to just [the important bits]. If the package name doesn't contain GNU I don't think it's needed to say it in the description either.
60 lines
1.9 KiB
Nix
60 lines
1.9 KiB
Nix
{ stdenv, fetchgit, autoconf, automake, libtool, pkgconfig, openconnect, file,
|
|
openvpn, vpnc, glib, dbus, iptables, gnutls, policykit, polkit,
|
|
wpa_supplicant, readline6, pptp, ppp, tree }:
|
|
|
|
stdenv.mkDerivation {
|
|
name = "connman-1.24";
|
|
src = fetchgit {
|
|
url = "git://git.kernel.org/pub/scm/network/connman/connman.git";
|
|
rev = "11b8a873988ab5fc3f360c5b6fb25a6761fe7683";
|
|
sha256 = "12z1krm5qnjyamc3qr2px7wvz7qkss7jk5brnmhyalqmcnkwcbrm";
|
|
};
|
|
|
|
buildInputs = [ autoconf automake libtool pkgconfig openconnect polkit
|
|
file openvpn vpnc glib dbus iptables gnutls policykit
|
|
wpa_supplicant readline6 pptp ppp tree ];
|
|
|
|
preConfigure = ''
|
|
export WPASUPPLICANT=${wpa_supplicant}/sbin/wpa_supplicant
|
|
./bootstrap
|
|
sed -i "s/\/usr\/bin\/file/file/g" ./configure
|
|
substituteInPlace configure --replace /usr/sbin/pptp ${pptp}/sbin/pptp
|
|
substituteInPlace configure --replace /usr/sbin/pppd ${ppp}/sbin/pppd
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--sysconfdir=\${out}/etc"
|
|
"--localstatedir=/var"
|
|
"--with-dbusconfdir=\${out}/etc"
|
|
"--with-dbusdatadir=\${out}/usr/share"
|
|
"--disable-maintainer-mode"
|
|
"--enable-openconnect=builtin"
|
|
"--with-openconnect=${openconnect}/sbin/openconnect"
|
|
"--enable-openvpn=builtin"
|
|
"--with-openvpn=${openvpn}/sbin/openvpn"
|
|
"--enable-vpnc=builtin"
|
|
"--with-vpnc=${vpnc}/sbin/vpnc"
|
|
"--enable-session-policy-local=builtin"
|
|
"--enable-client"
|
|
"--enable-bluetooth"
|
|
"--enable-wifi"
|
|
"--enable-polkit"
|
|
"--enable-tools"
|
|
"--enable-datafiles"
|
|
"--enable-pptp"
|
|
];
|
|
|
|
postInstall = ''
|
|
cp ./client/connmanctl $out/sbin/connmanctl
|
|
'';
|
|
|
|
meta = {
|
|
description = "Provides a daemon for managing internet connections";
|
|
homepage = "https://connman.net/";
|
|
maintainers = [ stdenv.lib.maintainers.matejc ];
|
|
# tested only on linux, might work on others also
|
|
platforms = stdenv.lib.platforms.linux;
|
|
license = stdenv.lib.licenses.gpl2;
|
|
};
|
|
}
|