1502152a7d
The indicator libraries for GTK2 and GTK3. The bindings for Mono do not work yet because of some issues with Perl in gtk-sharp-2 and an Unhandled Exception caused by building with multiple cores: https://aur.archlinux.org/packages/libindicate-sharp/#comment-290385 Some packages have TODOs for the indicator libraries, since it is an optional dependency for most packages. These packages have not been updated by this commit.
56 lines
1.6 KiB
Nix
56 lines
1.6 KiB
Nix
{ stdenv, fetchurl, lib, file
|
|
, pkgconfig, autoconf
|
|
, glib, dbus_glib, json_glib
|
|
, gtk3, libindicator-gtk3, libdbusmenu-gtk3, libappindicator-gtk3 }:
|
|
|
|
with lib;
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "indicator-application-gtk3-${version}";
|
|
version = "${versionMajor}.${versionMinor}";
|
|
versionMajor = "12.10";
|
|
versionMinor = "0";
|
|
|
|
src = fetchurl {
|
|
url = "${meta.homepage}/${versionMajor}/${version}/+download/indicator-application-${version}.tar.gz";
|
|
sha256 = "1z8ar0k47l4his7zvffbc2kn658nid51svqnfv0dms601w53gbpr";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkgconfig autoconf ];
|
|
|
|
buildInputs = [
|
|
glib dbus_glib json_glib
|
|
gtk3 libindicator-gtk3 libdbusmenu-gtk3 libappindicator-gtk3
|
|
];
|
|
|
|
postPatch = ''
|
|
substituteInPlace configure.ac \
|
|
--replace 'DBUSSERVICEDIR=`$PKG_CONFIG --variable=session_bus_services_dir dbus-1`' \
|
|
"DBUSSERVICEDIR=$out/share/dbus-1/services"
|
|
autoconf
|
|
substituteInPlace {configure,ltmain.sh,m4/libtool.m4} \
|
|
--replace /usr/bin/file ${file}/bin/file
|
|
substituteInPlace src/Makefile.in \
|
|
--replace 'applicationlibdir = $(INDICATORDIR)' "applicationlibdir = $out/lib"
|
|
'';
|
|
|
|
configureFlags = [
|
|
"CFLAGS=-Wno-error"
|
|
"--sysconfdir=/etc"
|
|
"--localstatedir=/var"
|
|
];
|
|
|
|
installFlags = [
|
|
"sysconfdir=\${out}/etc"
|
|
"localstatedir=\${TMPDIR}"
|
|
];
|
|
|
|
meta = {
|
|
description = "Indicator to take menus from applications and place them in the panel";
|
|
homepage = "https://launchpad.net/indicator-application";
|
|
license = licenses.gpl3;
|
|
platforms = platforms.linux;
|
|
maintainers = [ maintainers.msteen ];
|
|
};
|
|
}
|