bcfa59bf82
Updates gitlab to the current stable version and fixes a lot of features that were broken, at least with the current version and our configuration. Quite a lot of sweat and tears has gone into testing nearly all features and reading/patching the Gitlab source as we're about to deploy gitlab for our whole company. Things to note: * The gitlab config is now written as a nix attribute set and will be converted to JSON. Gitlab uses YAML but JSON is a subset of YAML. The `extraConfig` opition is also an attribute set that will be merged with the default config. This way *all* Gitlab options are supported. * Some paths like uploads and configs are hardcoded in rails (at least after my study of the Gitlab source). This is why they are linked from the Gitlab root to /run/gitlab and then linked to the configurable `statePath`. * Backup & restore should work out of the box from another Gitlab instance. * gitlab-git-http-server has been replaced by gitlab-workhorse upstream. Push & pull over HTTPS works perfectly. Communication to gitlab is done over unix sockets. An HTTP server is required to proxy requests to gitlab-workhorse over another unix socket at `/run/gitlab/gitlab-workhorse.socket`. * The user & group running gitlab are now configurable. These can even be changed for live instances. * The initial email address & password of the root user can be configured. Fixes #8598.
88 lines
2.3 KiB
Nix
88 lines
2.3 KiB
Nix
{ stdenv, lib, bundler, fetchFromGitHub, bundlerEnv, defaultGemConfig, libiconv, ruby
|
|
, tzdata, git, nodejs, procps
|
|
}:
|
|
|
|
/* When updating the Gemfile add `gem "activerecord-nulldb-adapter"`
|
|
to allow building the assets without a database */
|
|
|
|
let
|
|
env = bundlerEnv {
|
|
name = "gitlab";
|
|
inherit ruby;
|
|
gemfile = ./Gemfile;
|
|
lockfile = ./Gemfile.lock;
|
|
gemset = ./gemset.nix;
|
|
meta = with lib; {
|
|
homepage = http://www.gitlab.com/;
|
|
platforms = platforms.linux;
|
|
maintainers = [ ];
|
|
license = licenses.mit;
|
|
};
|
|
};
|
|
|
|
in
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "gitlab-${version}";
|
|
version = "8.5.0";
|
|
|
|
buildInputs = [ ruby bundler tzdata git nodejs procps ];
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "gitlabhq";
|
|
repo = "gitlabhq";
|
|
rev = "v${version}";
|
|
sha256 = "1rhl906xnvpxkw3ngwfzi80cl3daihx5vizy04b9b39adyd3i5hl";
|
|
};
|
|
|
|
patches = [
|
|
./remove-hardcoded-locations.patch
|
|
./disable-dump-schema-after-migration.patch
|
|
./nulladapter.patch
|
|
];
|
|
|
|
postPatch = ''
|
|
# For reasons I don't understand "bundle exec" ignores the
|
|
# RAILS_ENV causing tests to be executed that fail because we're
|
|
# not installing development and test gems above. Deleting the
|
|
# tests works though.:
|
|
rm lib/tasks/test.rake
|
|
|
|
rm config/initializers/gitlab_shell_secret_token.rb
|
|
|
|
substituteInPlace app/controllers/admin/background_jobs_controller.rb \
|
|
--replace "ps -U" "${procps}/bin/ps -U"
|
|
|
|
# required for some gems:
|
|
cat > config/database.yml <<EOF
|
|
production:
|
|
adapter: <%= ENV["GITLAB_DATABASE_ADAPTER"] || sqlite %>
|
|
database: gitlab
|
|
host: <%= ENV["GITLAB_DATABASE_HOST"] || "127.0.0.1" %>
|
|
password: <%= ENV["GITLAB_DATABASE_PASSWORD"] || "blerg" %>
|
|
username: gitlab
|
|
encoding: utf8
|
|
EOF
|
|
'';
|
|
|
|
buildPhase = ''
|
|
export GEM_HOME=${env}/${ruby.gemPath}
|
|
mv config/gitlab.yml.example config/gitlab.yml
|
|
GITLAB_DATABASE_ADAPTER=nulldb bundle exec rake assets:precompile RAILS_ENV=production
|
|
mv config/gitlab.yml config/gitlab.yml.example
|
|
mv config config.dist
|
|
'';
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/share
|
|
cp -r . $out/share/gitlab
|
|
ln -sf /run/gitlab/uploads $out/share/gitlab/public/uploads
|
|
ln -sf /run/gitlab/config $out/share/gitlab/config
|
|
'';
|
|
|
|
passthru = {
|
|
inherit env;
|
|
inherit ruby;
|
|
};
|
|
}
|