aecb983ebb
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/aws-sdk-cpp/versions. These checks were done: - built on NixOS - 0 of 0 passed binary check by having a zero exit code. - 0 of 0 passed binary check by having the new version present in output. - found 1.4.65 with grep in /nix/store/g0zw6fdmf5flpnd5mqqjk373ndlq1zwd-aws-sdk-cpp-1.4.65 - directory tree listing: https://gist.github.com/78023eae3b6e7a16a3b9e7fb7fdba55b - du listing: https://gist.github.com/2f4c13728002e11c5b08a8bc5658c21c
71 lines
2.1 KiB
Nix
71 lines
2.1 KiB
Nix
{ lib, stdenv, fetchFromGitHub, cmake, curl, openssl, zlib
|
|
, # Allow building a limited set of APIs, e.g. ["s3" "ec2"].
|
|
apis ? ["*"]
|
|
, # Whether to enable AWS' custom memory management.
|
|
customMemoryManagement ? true
|
|
, darwin
|
|
}:
|
|
|
|
let
|
|
loaderVar =
|
|
if stdenv.isLinux
|
|
then "LD_LIBRARY_PATH"
|
|
else if stdenv.isDarwin
|
|
then "DYLD_LIBRARY_PATH"
|
|
else throw "Unsupported system!";
|
|
in stdenv.mkDerivation rec {
|
|
name = "aws-sdk-cpp-${version}";
|
|
version = "1.4.65";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "awslabs";
|
|
repo = "aws-sdk-cpp";
|
|
rev = version;
|
|
sha256 = "0266d2gar9wi0p4plapcp4bms93nn61rdvpd8ik5h6hgqvdb3fl2";
|
|
};
|
|
|
|
# FIXME: might be nice to put different APIs in different outputs
|
|
# (e.g. libaws-cpp-sdk-s3.so in output "s3").
|
|
outputs = [ "out" "dev" ];
|
|
separateDebugInfo = stdenv.isLinux;
|
|
|
|
nativeBuildInputs = [ cmake curl ];
|
|
buildInputs = [ zlib curl openssl ]
|
|
++ lib.optionals (stdenv.isDarwin &&
|
|
((builtins.elem "text-to-speech" apis) ||
|
|
(builtins.elem "*" apis)))
|
|
(with darwin.apple_sdk.frameworks; [ CoreAudio AudioToolbox ]);
|
|
|
|
cmakeFlags =
|
|
lib.optional (!customMemoryManagement) "-DCUSTOM_MEMORY_MANAGEMENT=0"
|
|
++ lib.optional (stdenv.buildPlatform != stdenv.hostPlatform) "-DENABLE_TESTING=OFF"
|
|
++ lib.optional (apis != ["*"])
|
|
"-DBUILD_ONLY=${lib.concatStringsSep ";" apis}";
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
# Behold the escaping nightmare below on loaderVar o.O
|
|
preBuild =
|
|
''
|
|
# Ensure that the unit tests can find the *.so files.
|
|
for i in testing-resources aws-cpp-sdk-*; do
|
|
export ${loaderVar}=$(pwd)/$i:''${${loaderVar}}
|
|
done
|
|
'';
|
|
|
|
preConfigure =
|
|
''
|
|
rm aws-cpp-sdk-core-tests/aws/auth/AWSCredentialsProviderTest.cpp
|
|
'';
|
|
|
|
NIX_CFLAGS_COMPILE = [ "-Wno-error=noexcept-type" ];
|
|
|
|
meta = {
|
|
description = "A C++ interface for Amazon Web Services";
|
|
homepage = https://github.com/awslabs/aws-sdk-cpp;
|
|
license = lib.licenses.asl20;
|
|
platforms = lib.platforms.linux ++ lib.platforms.darwin;
|
|
maintainers = [ lib.maintainers.eelco ];
|
|
};
|
|
}
|