27aed1b642
libinput switched from Doxygen to Sphinx for user docs. Since Sphinx is a Python module, it propagates Python. And because it is listed in nativeBuildInputs, its python binary takes precedence over the one added in buildInputs. This results in a wrong interpreter being substituted into shebangs. The contamination occurred previously too but libinput does not use pyparsing dependency since 1.12.0, so it could be removed. I prevented Sphinx from propagating Python and added some additional dependencies to it. In the future we might want something more reusable. While at it, I also fixed the tests.
74 lines
2.5 KiB
Nix
74 lines
2.5 KiB
Nix
{ stdenv, fetchurl, pkgconfig, meson, ninja
|
|
, libevdev, mtdev, udev, libwacom
|
|
, documentationSupport ? false, doxygen ? null, graphviz ? null # Documentation
|
|
, eventGUISupport ? false, cairo ? null, glib ? null, gtk3 ? null # GUI event viewer support
|
|
, testsSupport ? false, check ? null, valgrind ? null, python3 ? null
|
|
}:
|
|
|
|
assert documentationSupport -> doxygen != null && graphviz != null && python3 != null;
|
|
assert eventGUISupport -> cairo != null && glib != null && gtk3 != null;
|
|
assert testsSupport -> check != null && valgrind != null && python3 != null;
|
|
|
|
let
|
|
mkFlag = optSet: flag: "-D${flag}=${stdenv.lib.boolToString optSet}";
|
|
|
|
sphinx-build = if documentationSupport then
|
|
python3.pkgs.sphinx.overrideAttrs (super: {
|
|
propagatedBuildInputs = super.propagatedBuildInputs ++ (with python3.pkgs; [ recommonmark sphinx_rtd_theme ]);
|
|
|
|
postFixup = super.postFixup or "" + ''
|
|
# Do not propagate Python
|
|
rm $out/nix-support/propagated-build-inputs
|
|
'';
|
|
})
|
|
else null;
|
|
in
|
|
|
|
with stdenv.lib;
|
|
stdenv.mkDerivation rec {
|
|
name = "libinput-${version}";
|
|
version = "1.12.3";
|
|
|
|
src = fetchurl {
|
|
url = "https://www.freedesktop.org/software/libinput/${name}.tar.xz";
|
|
sha256 = "0mg2zqbjcgj0aq7d9nwawvyhx43vakilahrc83hrfyif3a3gyrpj";
|
|
};
|
|
|
|
outputs = [ "bin" "out" "dev" ];
|
|
|
|
mesonFlags = [
|
|
(mkFlag documentationSupport "documentation")
|
|
(mkFlag eventGUISupport "debug-gui")
|
|
(mkFlag testsSupport "tests")
|
|
"--libexecdir=${placeholder "bin"}/libexec"
|
|
];
|
|
|
|
nativeBuildInputs = [ pkgconfig meson ninja ]
|
|
++ optionals documentationSupport [ doxygen graphviz sphinx-build ]
|
|
++ optionals testsSupport [ valgrind ];
|
|
|
|
buildInputs = [ libevdev mtdev libwacom (python3.withPackages (pkgs: with pkgs; [ evdev ])) ]
|
|
++ optionals eventGUISupport [ cairo glib gtk3 ]
|
|
++ optionals testsSupport [ check ];
|
|
|
|
propagatedBuildInputs = [ udev ];
|
|
|
|
patches = [ ./udev-absolute-path.patch ];
|
|
|
|
postPatch = ''
|
|
patchShebangs tools/helper-copy-and-exec-from-tmp.sh
|
|
patchShebangs test/symbols-leak-test
|
|
patchShebangs test/check-leftover-udev-rules.sh
|
|
'';
|
|
|
|
doCheck = testsSupport && stdenv.hostPlatform == stdenv.buildPlatform;
|
|
|
|
meta = {
|
|
description = "Handles input devices in Wayland compositors and provides a generic X.Org input driver";
|
|
homepage = http://www.freedesktop.org/wiki/Software/libinput;
|
|
license = licenses.mit;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ codyopel wkennington ];
|
|
};
|
|
}
|