4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
77 lines
1.9 KiB
Nix
77 lines
1.9 KiB
Nix
{ lib, stdenv, buildPythonPackage, fetchFromGitHub, isPy27
|
|
, glibcLocales, git
|
|
, mock, nose, markdown, lxml, typogrify
|
|
, jinja2, pygments, docutils, pytz, unidecode, six, dateutil, feedgenerator
|
|
, blinker, pillow, beautifulsoup4, markupsafe, pandoc }:
|
|
|
|
buildPythonPackage rec {
|
|
pname = "pelican";
|
|
version = "4.5.0";
|
|
|
|
disabled = isPy27;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "getpelican";
|
|
repo = "pelican";
|
|
rev = version;
|
|
sha256 = "0p8p84fcpkr19d54dhxvldd8ijbg334wmrmkr99pnbrdl1gf64qi";
|
|
# Remove unicode file names which leads to different checksums on HFS+
|
|
# vs. other filesystems because of unicode normalisation.
|
|
extraPostFetch = ''
|
|
rm -r $out/pelican/tests/output/custom_locale/posts
|
|
'';
|
|
};
|
|
|
|
doCheck = true;
|
|
|
|
# Exclude custom locale test, which files were removed above to fix the source checksum
|
|
checkPhase = ''
|
|
nosetests -s \
|
|
--exclude=test_custom_locale_generation_works \
|
|
--exclude=test_log_filter \
|
|
pelican
|
|
'';
|
|
|
|
buildInputs = [
|
|
glibcLocales
|
|
pandoc
|
|
git
|
|
mock
|
|
markdown
|
|
typogrify
|
|
];
|
|
|
|
propagatedBuildInputs = [
|
|
jinja2 pygments docutils pytz unidecode six dateutil feedgenerator
|
|
blinker pillow beautifulsoup4 markupsafe lxml
|
|
];
|
|
|
|
checkInputs = [
|
|
nose
|
|
pandoc
|
|
];
|
|
|
|
postPatch= ''
|
|
substituteInPlace pelican/tests/test_pelican.py \
|
|
--replace "'git'" "'${git}/bin/git'"
|
|
'';
|
|
|
|
LC_ALL="en_US.UTF-8";
|
|
|
|
# We only want to patch shebangs in /bin, and not those
|
|
# of the project scripts that are created by Pelican.
|
|
# See https://github.com/NixOS/nixpkgs/issues/30116
|
|
dontPatchShebangs = true;
|
|
|
|
postFixup = ''
|
|
patchShebangs $out/bin
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "A tool to generate a static blog from reStructuredText or Markdown input files";
|
|
homepage = "http://getpelican.com/";
|
|
license = licenses.agpl3;
|
|
maintainers = with maintainers; [ offline prikhi ];
|
|
};
|
|
}
|