723f7f8f4f
If no config.nix.storeDir has been set, don't fall back to "/nix/store" but use builtins.storeDir instead so we always should end up with the correct store path no matter whether config.nix.storeDir has been set. Thanks to @lethalman for pointing this out. Signed-off-by: aszlig <aszlig@redmoonstudios.org>
58 lines
1.9 KiB
Nix
58 lines
1.9 KiB
Nix
{ stdenv, fetchurl, glib, flex, bison, pkgconfig, libffi, python
|
|
, libintlOrEmpty, autoconf, automake, otool
|
|
, substituteAll, nixStoreDir ? builtins.storeDir
|
|
}:
|
|
# now that gobjectIntrospection creates large .gir files (eg gtk3 case)
|
|
# it may be worth thinking about using multiple derivation outputs
|
|
# In that case its about 6MB which could be separated
|
|
|
|
let
|
|
ver_maj = "1.46";
|
|
ver_min = "0";
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
name = "gobject-introspection-${ver_maj}.${ver_min}";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://gnome/sources/gobject-introspection/${ver_maj}/${name}.tar.xz";
|
|
sha256 = "6658bd3c2b8813eb3e2511ee153238d09ace9d309e4574af27443d87423e4233";
|
|
};
|
|
|
|
buildInputs = [ flex bison pkgconfig python ]
|
|
++ libintlOrEmpty
|
|
++ stdenv.lib.optional stdenv.isDarwin otool;
|
|
propagatedBuildInputs = [ libffi glib ];
|
|
|
|
# Tests depend on cairo, which is undesirable (it pulls in lots of
|
|
# other dependencies).
|
|
configureFlags = [ "--disable-tests" ];
|
|
|
|
preConfigure = ''
|
|
sed 's|/usr/bin/env ||' -i tools/g-ir-tool-template.in
|
|
'';
|
|
|
|
postInstall = "rm -rf $out/share/gtk-doc";
|
|
|
|
setupHook = ./setup-hook.sh;
|
|
|
|
patches = stdenv.lib.singleton (substituteAll {
|
|
src = ./absolute_shlib_path.patch;
|
|
inherit nixStoreDir;
|
|
});
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "A middleware layer between C libraries and language bindings";
|
|
homepage = http://live.gnome.org/GObjectIntrospection;
|
|
maintainers = with maintainers; [ lovek323 urkud lethalman ];
|
|
platforms = platforms.unix;
|
|
|
|
longDescription = ''
|
|
GObject introspection is a middleware layer between C libraries (using
|
|
GObject) and language bindings. The C library can be scanned at compile
|
|
time and generate a metadata file, in addition to the actual native C
|
|
library. Then at runtime, language bindings can read this metadata and
|
|
automatically provide bindings to call into the C library.
|
|
'';
|
|
};
|
|
}
|