4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
51 lines
1.6 KiB
Nix
51 lines
1.6 KiB
Nix
{ lib, stdenv, buildPythonPackage, pythonOlder, fetchPypi, attrs, hypothesis, py
|
|
, setuptools_scm, setuptools, six, pluggy, funcsigs, isPy3k, more-itertools
|
|
, atomicwrites, mock, writeText, pathlib2, wcwidth, packaging, isPyPy
|
|
}:
|
|
buildPythonPackage rec {
|
|
version = "4.6.11";
|
|
pname = "pytest";
|
|
|
|
src = fetchPypi {
|
|
inherit pname version;
|
|
sha256 = "50fa82392f2120cc3ec2ca0a75ee615be4c479e66669789771f1758332be4353";
|
|
};
|
|
|
|
checkInputs = [ hypothesis mock ];
|
|
buildInputs = [ setuptools_scm ];
|
|
propagatedBuildInputs = [ attrs py setuptools six pluggy more-itertools atomicwrites wcwidth packaging ]
|
|
++ stdenv.lib.optionals (!isPy3k) [ funcsigs ]
|
|
++ stdenv.lib.optionals (pythonOlder "3.6") [ pathlib2 ];
|
|
|
|
doCheck = !isPyPy; # https://github.com/pytest-dev/pytest/issues/3460
|
|
checkPhase = ''
|
|
runHook preCheck
|
|
|
|
# don't test bash builtins
|
|
rm testing/test_argcomplete.py
|
|
|
|
# determinism - this test writes non deterministic bytecode
|
|
rm -rf testing/test_assertrewrite.py
|
|
|
|
PYTHONDONTWRITEBYTECODE=1 $out/bin/py.test -x testing/ -k "not test_collect_pyargs_with_testpaths"
|
|
runHook postCheck
|
|
'';
|
|
|
|
# Remove .pytest_cache when using py.test in a Nix build
|
|
setupHook = writeText "pytest-hook" ''
|
|
pytestcachePhase() {
|
|
find $out -name .pytest_cache -type d -exec rm -rf {} +
|
|
}
|
|
|
|
preDistPhases+=" pytestcachePhase"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://docs.pytest.org";
|
|
description = "Framework for writing tests";
|
|
maintainers = with maintainers; [ domenkozar lovek323 madjar lsix ];
|
|
license = licenses.mit;
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|