47 lines
1.5 KiB
Nix
47 lines
1.5 KiB
Nix
{ stdenv, fetchurl, pkgconfig, pcre, libxml2, zlib, attr, bzip2, which, file
|
|
, openssl, enableMagnet ? false, lua5_1 ? null
|
|
, enableMysql ? false, mysql ? null
|
|
}:
|
|
|
|
assert enableMagnet -> lua5_1 != null;
|
|
assert enableMysql -> mysql != null;
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "lighttpd-1.4.45";
|
|
|
|
src = fetchurl {
|
|
url = "http://download.lighttpd.net/lighttpd/releases-1.4.x/${name}.tar.xz";
|
|
sha256 = "0grsqh7pdqnjx6xicd96adsx84vryb7c4n21dnxfygm3xrfj55qw";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [ pcre libxml2 zlib attr bzip2 which file openssl ]
|
|
++ stdenv.lib.optional enableMagnet lua5_1
|
|
++ stdenv.lib.optional enableMysql mysql.lib;
|
|
|
|
configureFlags = [ "--with-openssl" ]
|
|
++ stdenv.lib.optional enableMagnet "--with-lua"
|
|
++ stdenv.lib.optional enableMysql "--with-mysql";
|
|
|
|
preConfigure = ''
|
|
sed -i "s:/usr/bin/file:${file}/bin/file:g" configure
|
|
'';
|
|
|
|
postInstall = ''
|
|
mkdir -p "$out/share/lighttpd/doc/config"
|
|
cp -vr doc/config "$out/share/lighttpd/doc/"
|
|
# Remove files that references needless store paths (dependency bloat)
|
|
rm "$out/share/lighttpd/doc/config/Makefile"*
|
|
rm "$out/share/lighttpd/doc/config/conf.d/Makefile"*
|
|
rm "$out/share/lighttpd/doc/config/vhosts.d/Makefile"*
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Lightweight high-performance web server";
|
|
homepage = http://www.lighttpd.net/;
|
|
license = stdenv.lib.licenses.bsd3;
|
|
platforms = platforms.linux;
|
|
maintainers = [ maintainers.bjornfor ];
|
|
};
|
|
}
|