46 lines
1.3 KiB
Nix
46 lines
1.3 KiB
Nix
{ stdenv, fetchFromGitHub }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "jdupes";
|
|
version = "1.14.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "jbruchon";
|
|
repo = "jdupes";
|
|
rev = "v${version}";
|
|
sha256 = "18hn25f7cdz1li0vvx74al7a8z2220xhzjp9j6idhldsmjnscgq8";
|
|
# Unicode file names lead to different checksums on HFS+ vs. other
|
|
# filesystems because of unicode normalisation. The testdir
|
|
# directories have such files and will be removed.
|
|
extraPostFetch = "rm -r $out/testdir";
|
|
};
|
|
|
|
makeFlags = [
|
|
"PREFIX=${placeholder "out"}"
|
|
] ++ stdenv.lib.optionals stdenv.isLinux [
|
|
"ENABLE_DEDUPE=1"
|
|
"STATIC_DEDUPE_H=1"
|
|
];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
doCheck = false; # broken Makefile, the above also removes tests
|
|
|
|
postInstall = ''
|
|
install -Dm644 -t $out/share/doc/jdupes CHANGES LICENSE README.md
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "A powerful duplicate file finder and an enhanced fork of 'fdupes'";
|
|
longDescription = ''
|
|
jdupes is a program for identifying and taking actions upon
|
|
duplicate files. This fork known as 'jdupes' is heavily modified
|
|
from and improved over the original.
|
|
'';
|
|
homepage = "https://github.com/jbruchon/jdupes";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ romildo ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|