ba52ae5048
Following legacy packing conventions, `isArm` was defined just for
32-bit ARM instruction set. This is confusing to non packagers though,
because Aarch64 is an ARM instruction set.
The official ARM overview for ARMv8[1] is surprisingly not confusing,
given the overall state of affairs for ARM naming conventions, and
offers us a solution. It divides the nomenclature into three levels:
```
ISA: ARMv8 {-A, -R, -M}
/ \
Mode: Aarch32 Aarch64
| / \
Encoding: A64 A32 T32
```
At the top is the overall v8 instruction set archicture. Second are the
two modes, defined by bitwidth but differing in other semantics too, and
buttom are the encodings, (hopefully?) isomorphic if they encode the
same mode.
The 32 bit encodings are mostly backwards compatible with previous
non-Thumb and Thumb encodings, and if so we can pun the mode names to
instead mean "sets of compatable or isomorphic encodings", and then
voilà we have nice names for 32-bit and 64-bit arm instruction sets
which do not use the word ARM so as to not confused either laymen or
experienced ARM packages.
[1]: https://developer.arm.com/products/architecture/a-profile
149 lines
4.9 KiB
Nix
149 lines
4.9 KiB
Nix
let lib = import ../../../lib; in lib.makeOverridable (
|
|
|
|
{ name ? "stdenv", preHook ? "", initialPath, cc, shell
|
|
, allowedRequisites ? null, extraAttrs ? {}, overrides ? (self: super: {}), config
|
|
|
|
, # The `fetchurl' to use for downloading curl and its dependencies
|
|
# (see all-packages.nix).
|
|
fetchurlBoot
|
|
|
|
, setupScript ? ./setup.sh
|
|
|
|
, extraNativeBuildInputs ? []
|
|
, extraBuildInputs ? []
|
|
, __stdenvImpureHostDeps ? []
|
|
, __extraImpureHostDeps ? []
|
|
, stdenvSandboxProfile ? ""
|
|
, extraSandboxProfile ? ""
|
|
|
|
## Platform parameters
|
|
##
|
|
## The "build" "host" "target" terminology below comes from GNU Autotools. See
|
|
## its documentation for more information on what those words mean. Note that
|
|
## each should always be defined, even when not cross compiling.
|
|
##
|
|
## For purposes of bootstrapping, think of each stage as a "sliding window"
|
|
## over a list of platforms. Specifically, the host platform of the previous
|
|
## stage becomes the build platform of the current one, and likewise the
|
|
## target platform of the previous stage becomes the host platform of the
|
|
## current one.
|
|
##
|
|
|
|
, # The platform on which packages are built. Consists of `system`, a
|
|
# string (e.g.,`i686-linux') identifying the most import attributes of the
|
|
# build platform, and `platform` a set of other details.
|
|
buildPlatform
|
|
|
|
, # The platform on which packages run.
|
|
hostPlatform
|
|
|
|
, # The platform which build tools (especially compilers) build for in this stage,
|
|
targetPlatform
|
|
}:
|
|
|
|
let
|
|
defaultNativeBuildInputs = extraNativeBuildInputs ++
|
|
[ ../../build-support/setup-hooks/move-docs.sh
|
|
../../build-support/setup-hooks/compress-man-pages.sh
|
|
../../build-support/setup-hooks/strip.sh
|
|
../../build-support/setup-hooks/patch-shebangs.sh
|
|
]
|
|
# FIXME this on Darwin; see
|
|
# https://github.com/NixOS/nixpkgs/commit/94d164dd7#commitcomment-22030369
|
|
++ lib.optional hostPlatform.isLinux ../../build-support/setup-hooks/audit-tmpdir.sh
|
|
++ [
|
|
../../build-support/setup-hooks/multiple-outputs.sh
|
|
../../build-support/setup-hooks/move-sbin.sh
|
|
../../build-support/setup-hooks/move-lib64.sh
|
|
../../build-support/setup-hooks/set-source-date-epoch-to-latest.sh
|
|
cc
|
|
];
|
|
|
|
defaultBuildInputs = extraBuildInputs;
|
|
|
|
# The stdenv that we are producing.
|
|
stdenv =
|
|
derivation (
|
|
lib.optionalAttrs (allowedRequisites != null) {
|
|
allowedRequisites = allowedRequisites
|
|
++ defaultNativeBuildInputs ++ defaultBuildInputs;
|
|
}
|
|
// {
|
|
inherit name;
|
|
|
|
# Nix itself uses the `system` field of a derivation to decide where to
|
|
# build it. This is a bit confusing for cross compilation.
|
|
inherit (buildPlatform) system;
|
|
|
|
builder = shell;
|
|
|
|
args = ["-e" ./builder.sh];
|
|
|
|
setup = setupScript;
|
|
|
|
# We pretty much never need rpaths on Darwin, since all library path references
|
|
# are absolute unless we go out of our way to make them relative (like with CF)
|
|
# TODO: This really wants to be in stdenv/darwin but we don't have hostPlatform
|
|
# there (yet?) so it goes here until then.
|
|
preHook = preHook+ lib.optionalString buildPlatform.isDarwin ''
|
|
export NIX_BUILD_DONT_SET_RPATH=1
|
|
'' + lib.optionalString hostPlatform.isDarwin ''
|
|
export NIX_DONT_SET_RPATH=1
|
|
export NIX_NO_SELF_RPATH=1
|
|
'' + lib.optionalString targetPlatform.isDarwin ''
|
|
export NIX_TARGET_DONT_SET_RPATH=1
|
|
'';
|
|
|
|
inherit initialPath shell
|
|
defaultNativeBuildInputs defaultBuildInputs;
|
|
}
|
|
// lib.optionalAttrs buildPlatform.isDarwin {
|
|
__sandboxProfile = stdenvSandboxProfile;
|
|
__impureHostDeps = __stdenvImpureHostDeps;
|
|
})
|
|
|
|
// rec {
|
|
|
|
meta = {
|
|
description = "The default build environment for Unix packages in Nixpkgs";
|
|
platforms = lib.platforms.all;
|
|
};
|
|
|
|
inherit buildPlatform hostPlatform targetPlatform;
|
|
|
|
inherit extraNativeBuildInputs extraBuildInputs
|
|
__extraImpureHostDeps extraSandboxProfile;
|
|
|
|
# Utility flags to test the type of platform.
|
|
inherit (hostPlatform)
|
|
isDarwin isLinux isSunOS isHurd isCygwin isFreeBSD isOpenBSD
|
|
isi686 isx86_64 is64bit isAarch32 isAarch64 isMips isBigEndian;
|
|
|
|
# Whether we should run paxctl to pax-mark binaries.
|
|
needsPax = isLinux;
|
|
|
|
inherit (import ./make-derivation.nix {
|
|
inherit lib config stdenv;
|
|
}) mkDerivation;
|
|
|
|
# For convenience, bring in the library functions in lib/ so
|
|
# packages don't have to do that themselves.
|
|
inherit lib;
|
|
|
|
inherit fetchurlBoot;
|
|
|
|
inherit overrides;
|
|
|
|
inherit cc;
|
|
|
|
isCross = targetPlatform != buildPlatform;
|
|
}
|
|
|
|
# Propagate any extra attributes. For instance, we use this to
|
|
# "lift" packages like curl from the final stdenv for Linux to
|
|
# all-packages.nix for that platform (meaning that it has a line
|
|
# like curl = if stdenv ? curl then stdenv.curl else ...).
|
|
// extraAttrs;
|
|
|
|
in stdenv)
|