4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
64 lines
1.7 KiB
Nix
64 lines
1.7 KiB
Nix
{ lib, stdenv, fetchurl, writeText, plugins ? [ ] }:
|
|
|
|
let
|
|
version = "3.10";
|
|
stableVersion = lib.concatStrings (lib.take 2 (lib.splitVersion version));
|
|
|
|
in stdenv.mkDerivation rec {
|
|
pname = "moodle";
|
|
inherit version;
|
|
|
|
src = fetchurl {
|
|
url =
|
|
"https://download.moodle.org/stable${stableVersion}/${pname}-${version}.tgz";
|
|
sha256 = "4aYKZmXym1Tq/462PIgJb4sHGUclEkU0Ok1iQJ6u0aw=";
|
|
};
|
|
|
|
phpConfig = writeText "config.php" ''
|
|
<?php
|
|
return require(getenv('MOODLE_CONFIG'));
|
|
?>
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/share/moodle
|
|
cp -r . $out/share/moodle
|
|
cp ${phpConfig} $out/share/moodle/config.php
|
|
|
|
${lib.concatStringsSep "\n" (map (p:
|
|
let
|
|
dir = if p.pluginType == "mod" then
|
|
"mod"
|
|
else if p.pluginType == "theme" then
|
|
"theme"
|
|
else if p.pluginType == "block" then
|
|
"blocks"
|
|
else if p.pluginType == "question" then
|
|
"question/type"
|
|
else if p.pluginType == "course" then
|
|
"course/format"
|
|
else if p.pluginType == "report" then
|
|
"admin/report"
|
|
else
|
|
throw "unknown moodle plugin type";
|
|
# we have to copy it, because the plugins have refrences to .. inside
|
|
in ''
|
|
mkdir -p $out/share/moodle/${dir}/${p.name}
|
|
cp -r ${p}/* $out/share/moodle/${dir}/${p.name}/
|
|
'') plugins)}
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description =
|
|
"Free and open-source learning management system (LMS) written in PHP";
|
|
license = licenses.gpl3Plus;
|
|
homepage = "https://moodle.org/";
|
|
maintainers = with maintainers; [ freezeboy ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|