89023c38fc
I made a mistake merge. Reverting it inc778945806undid the state on master, but now I realize it crippled the git merge mechanism. As the merge contained a mix of commits from `master..staging-next` and other commits from `staging-next..staging`, it got the `staging-next` branch into a state that was difficult to recover. I reconstructed the "desired" state of staging-next tree by: - checking out the last commit of the problematic range:4effe769e2- `git rebase -i --preserve-merges a8a018ddc0` - dropping the mistaken merge commit and its revert from that range (while keeping reapplication from4effe769e2) - merging the last unaffected staging-next commit (803ca85c20) - fortunately no other commits have been pushed to staging-next yet - applying a diff on staging-next to get it into that state
88 lines
2.5 KiB
Nix
88 lines
2.5 KiB
Nix
{ stdenv, fetchFromGitHub, pkgconfig, glib, freetype, cairo, libintl
|
|
, meson, ninja
|
|
, gobject-introspection
|
|
, icu, graphite2, harfbuzz # The icu variant uses and propagates the non-icu one.
|
|
, ApplicationServices, CoreText
|
|
, withCoreText ? false
|
|
, withIcu ? false # recommended by upstream as default, but most don't needed and it's big
|
|
, withGraphite2 ? true # it is small and major distros do include it
|
|
, python3
|
|
, gtk-doc, docbook-xsl-nons, docbook_xml_dtd_43
|
|
}:
|
|
|
|
let
|
|
version = "2.7.2";
|
|
inherit (stdenv.lib) optional optionals optionalString;
|
|
mesonFeatureFlag = opt: b:
|
|
"-D${opt}=${if b then "enabled" else "disabled"}";
|
|
in
|
|
|
|
stdenv.mkDerivation {
|
|
name = "harfbuzz${optionalString withIcu "-icu"}-${version}";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "harfbuzz";
|
|
repo = "harfbuzz";
|
|
rev = version;
|
|
sha256 = "0vfyxr3lvzp80j1347nrwpr1ndv265p15rj2q8rj31lb26nyz4dm";
|
|
};
|
|
|
|
postPatch = ''
|
|
patchShebangs src/*.py
|
|
patchShebangs test
|
|
'' + stdenv.lib.optionalString stdenv.isDarwin ''
|
|
# ApplicationServices.framework headers have cast-align warnings.
|
|
substituteInPlace src/hb.hh \
|
|
--replace '#pragma GCC diagnostic error "-Wcast-align"' ""
|
|
'';
|
|
|
|
outputs = [ "out" "dev" "devdoc" ];
|
|
outputBin = "dev";
|
|
|
|
mesonFlags = [
|
|
(mesonFeatureFlag "graphite" withGraphite2)
|
|
(mesonFeatureFlag "icu" withIcu)
|
|
(mesonFeatureFlag "coretext" withCoreText)
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
meson
|
|
ninja
|
|
gobject-introspection
|
|
libintl
|
|
pkgconfig
|
|
python3
|
|
gtk-doc
|
|
docbook-xsl-nons
|
|
docbook_xml_dtd_43
|
|
];
|
|
|
|
buildInputs = [ glib freetype cairo ] # recommended by upstream
|
|
++ stdenv.lib.optionals withCoreText [ ApplicationServices CoreText ];
|
|
|
|
propagatedBuildInputs = []
|
|
++ optional withGraphite2 graphite2
|
|
++ optionals withIcu [ icu harfbuzz ];
|
|
|
|
doCheck = true;
|
|
|
|
# Slightly hacky; some pkgs expect them in a single directory.
|
|
postFixup = optionalString withIcu ''
|
|
rm "$out"/lib/libharfbuzz.* "$dev/lib/pkgconfig/harfbuzz.pc"
|
|
ln -s {'${harfbuzz.out}',"$out"}/lib/libharfbuzz.la
|
|
ln -s {'${harfbuzz.dev}',"$dev"}/lib/pkgconfig/harfbuzz.pc
|
|
${optionalString stdenv.isDarwin ''
|
|
ln -s {'${harfbuzz.out}',"$out"}/lib/libharfbuzz.dylib
|
|
ln -s {'${harfbuzz.out}',"$out"}/lib/libharfbuzz.0.dylib
|
|
''}
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "An OpenType text shaping engine";
|
|
homepage = "https://harfbuzz.github.io/";
|
|
maintainers = [ maintainers.eelco ];
|
|
license = licenses.mit;
|
|
platforms = with platforms; linux ++ darwin;
|
|
};
|
|
}
|