d02c2d694e
3d040f9305 removed it from installation-device.nix, but the default
loglevel is just too low for ARM and the like.
66 lines
2.2 KiB
Nix
66 lines
2.2 KiB
Nix
# To build, use:
|
|
# nix-build nixos -I nixos-config=nixos/modules/installer/cd-dvd/sd-image-aarch64.nix -A config.system.build.sdImage
|
|
{ config, lib, pkgs, ... }:
|
|
|
|
let
|
|
extlinux-conf-builder =
|
|
import ../../system/boot/loader/generic-extlinux-compatible/extlinux-conf-builder.nix {
|
|
inherit pkgs;
|
|
};
|
|
in
|
|
{
|
|
imports = [
|
|
../../profiles/base.nix
|
|
../../profiles/installation-device.nix
|
|
./sd-image.nix
|
|
];
|
|
|
|
assertions = lib.singleton {
|
|
assertion = pkgs.stdenv.system == "aarch64-linux";
|
|
message = "sd-image-aarch64.nix can be only built natively on Aarch64 / ARM64; " +
|
|
"it cannot be cross compiled";
|
|
};
|
|
|
|
# Needed by RPi firmware
|
|
nixpkgs.config.allowUnfree = true;
|
|
|
|
boot.loader.grub.enable = false;
|
|
boot.loader.generic-extlinux-compatible.enable = true;
|
|
|
|
boot.consoleLogLevel = lib.mkDefault 7;
|
|
boot.kernelPackages = pkgs.linuxPackages_latest;
|
|
|
|
# The serial ports listed here are:
|
|
# - ttyS0: for Tegra (Jetson TX1)
|
|
# - ttyAMA0: for QEMU's -machine virt
|
|
# Also increase the amount of CMA to ensure the virtual console on the RPi3 works.
|
|
boot.kernelParams = ["cma=32M" "console=ttyS0,115200n8" "console=ttyAMA0,115200n8" "console=tty0"];
|
|
|
|
# FIXME: this probably should be in installation-device.nix
|
|
users.extraUsers.root.initialHashedPassword = "";
|
|
|
|
sdImage = {
|
|
populateBootCommands = let
|
|
configTxt = pkgs.writeText "config.txt" ''
|
|
kernel=u-boot-rpi3.bin
|
|
|
|
# Boot in 64-bit mode.
|
|
arm_control=0x200
|
|
|
|
# U-Boot used to need this to work, regardless of whether UART is actually used or not.
|
|
# TODO: check when/if this can be removed.
|
|
enable_uart=1
|
|
|
|
# Prevent the firmware from smashing the framebuffer setup done by the mainline kernel
|
|
# when attempting to show low-voltage or overtemperature warnings.
|
|
avoid_warnings=1
|
|
'';
|
|
in ''
|
|
(cd ${pkgs.raspberrypifw}/share/raspberrypi/boot && cp bootcode.bin fixup*.dat start*.elf $NIX_BUILD_TOP/boot/)
|
|
cp ${pkgs.ubootRaspberryPi3_64bit}/u-boot.bin boot/u-boot-rpi3.bin
|
|
cp ${configTxt} boot/config.txt
|
|
${extlinux-conf-builder} -t 3 -c ${config.system.build.toplevel} -d ./boot
|
|
'';
|
|
};
|
|
}
|