1a59c8d09c
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/harfbuzz/versions. These checks were done: - built on NixOS - Warning: no binary found that responded to help or version flags. (This warning appears even if the package isn't expected to have binaries.) - found 1.7.6 with grep in /nix/store/q29jj339iyq46gh6dx7zrpbgx07b7826-harfbuzz-1.7.6 - directory tree listing: https://gist.github.com/ea2a4f299a574853f5fa5137ff8505ca
57 lines
2.0 KiB
Nix
57 lines
2.0 KiB
Nix
{ stdenv, fetchurl, pkgconfig, glib, freetype, cairo, libintlOrEmpty
|
|
, icu, graphite2, harfbuzz # The icu variant uses and propagates the non-icu one.
|
|
, withIcu ? false # recommended by upstream as default, but most don't needed and it's big
|
|
, withGraphite2 ? true # it is small and major distros do include it
|
|
}:
|
|
|
|
let
|
|
version = "1.7.6";
|
|
inherit (stdenv.lib) optional optionals optionalString;
|
|
in
|
|
|
|
stdenv.mkDerivation {
|
|
name = "harfbuzz${optionalString withIcu "-icu"}-${version}";
|
|
|
|
src = fetchurl {
|
|
url = "http://www.freedesktop.org/software/harfbuzz/release/harfbuzz-${version}.tar.bz2";
|
|
sha256 = "16rf7qwgy1gza74v2ws79zdwwb1lpvgz2abwwm8ws9j82cwysyys";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ];
|
|
outputBin = "dev";
|
|
|
|
configureFlags = [
|
|
( "--with-graphite2=" + (if withGraphite2 then "yes" else "no") ) # not auto-detected by default
|
|
( "--with-icu=" + (if withIcu then "yes" else "no") )
|
|
];
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [ glib freetype cairo ] # recommended by upstream
|
|
++ libintlOrEmpty;
|
|
propagatedBuildInputs = []
|
|
++ optional withGraphite2 graphite2
|
|
++ optionals withIcu [ icu harfbuzz ]
|
|
;
|
|
|
|
# Slightly hacky; some pkgs expect them in a single directory.
|
|
postInstall = optionalString withIcu ''
|
|
rm "$out"/lib/libharfbuzz.* "$dev/lib/pkgconfig/harfbuzz.pc"
|
|
ln -s {'${harfbuzz.out}',"$out"}/lib/libharfbuzz.la
|
|
ln -s {'${harfbuzz.dev}',"$dev"}/lib/pkgconfig/harfbuzz.pc
|
|
${optionalString stdenv.isDarwin ''
|
|
ln -s {'${harfbuzz.out}',"$out"}/lib/libharfbuzz.dylib
|
|
ln -s {'${harfbuzz.out}',"$out"}/lib/libharfbuzz.0.dylib
|
|
''}
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "An OpenType text shaping engine";
|
|
homepage = http://www.freedesktop.org/wiki/Software/HarfBuzz;
|
|
downloadPage = "https://www.freedesktop.org/software/harfbuzz/release/";
|
|
maintainers = [ maintainers.eelco ];
|
|
platforms = with platforms; linux ++ darwin;
|
|
inherit version;
|
|
updateWalker = true;
|
|
};
|
|
}
|