87 lines
2.3 KiB
Nix
87 lines
2.3 KiB
Nix
{ config, lib, stdenv
|
|
, fetchurl
|
|
, autoPatchelfHook
|
|
, makeWrapper
|
|
|
|
, alsa-lib
|
|
, gtk3
|
|
, lame
|
|
, ffmpeg
|
|
, vlc
|
|
, xdg-utils
|
|
, which
|
|
|
|
, jackSupport ? true
|
|
, jackLibrary
|
|
, pulseaudioSupport ? config.pulseaudio or true
|
|
, libpulseaudio
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "reaper";
|
|
version = "6.61";
|
|
|
|
src = fetchurl {
|
|
url = "https://www.reaper.fm/files/${lib.versions.major version}.x/reaper${builtins.replaceStrings ["."] [""] version}_linux_${stdenv.hostPlatform.qemuArch}.tar.xz";
|
|
hash = {
|
|
x86_64-linux = "sha256-Lp2EVky1+ruc86LdMmvhZIisoYl0OxdkVnN3h/u09IQ=";
|
|
aarch64-linux = "sha256-sPLCMA//xAdWXjY7++R6eLWS56Zi0u+9ju7JlICGvVc=";
|
|
}.${stdenv.hostPlatform.system};
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
autoPatchelfHook
|
|
makeWrapper
|
|
xdg-utils # Required for desktop integration
|
|
which
|
|
];
|
|
|
|
buildInputs = [
|
|
alsa-lib
|
|
stdenv.cc.cc.lib # reaper and libSwell need libstdc++.so.6
|
|
gtk3
|
|
];
|
|
|
|
runtimeDependencies = [
|
|
gtk3 # libSwell needs libgdk-3.so.0
|
|
]
|
|
++ lib.optional jackSupport jackLibrary
|
|
++ lib.optional pulseaudioSupport libpulseaudio;
|
|
|
|
dontBuild = true;
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
HOME="$out/share" XDG_DATA_HOME="$out/share" ./install-reaper.sh \
|
|
--install $out/opt \
|
|
--integrate-user-desktop
|
|
rm $out/opt/REAPER/uninstall-reaper.sh
|
|
|
|
# Dynamic loading of plugin dependencies does not adhere to rpath of
|
|
# reaper executable that gets modified with runtimeDependencies.
|
|
# Patching each plugin with DT_NEEDED is cumbersome and requires
|
|
# hardcoding of API versions of each dependency.
|
|
# Setting the rpath of the plugin shared object files does not
|
|
# seem to have an effect for some plugins.
|
|
# We opt for wrapping the executable with LD_LIBRARY_PATH prefix.
|
|
wrapProgram $out/opt/REAPER/reaper \
|
|
--prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath [ lame ffmpeg vlc ]}"
|
|
|
|
mkdir $out/bin
|
|
ln -s $out/opt/REAPER/reaper $out/bin/
|
|
ln -s $out/opt/REAPER/reamote-server $out/bin/
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Digital audio workstation";
|
|
homepage = "https://www.reaper.fm/";
|
|
sourceProvenance = with sourceTypes; [ binaryNativeCode ];
|
|
license = licenses.unfree;
|
|
platforms = [ "x86_64-linux" "aarch64-linux" ];
|
|
maintainers = with maintainers; [ jfrankenau ilian orivej uniquepointer viraptor ];
|
|
};
|
|
}
|