python3Packages.py-desmume: init at 0.0.3.post2

pkgs/development/python-modules/py-desmume/default.nix

@@ -0,0 +1,44 @@
+{ lib, buildPythonPackage, fetchFromGitHub, GitPython
+, libpcap, meson, ninja, pillow, pkg-config, pygobject3, SDL2
+, alsaLib, soundtouch, openal
+}:
+
+let
+  desmume = fetchFromGitHub {
+    owner = "SkyTemple";
+    repo = "desmume";
+    rev = "8e7af8ada883b7e91344985236f7c7c04ee795d7";
+    sha256 = "0svmv2rch9q347gbpbws4agymas8n014gh1ssaf91wx7jwn53842";
+  };
+in
+buildPythonPackage rec {
+  pname = "py-desmume";
+  version = "0.0.3.post2";
+
+  src = fetchFromGitHub {
+    owner = "SkyTemple";
+    repo = pname;
+    rev = version;
+    sha256 = "1chsg70k8kqnlasn88b04ww3yl0lay1bjxvz6lhp6s2cvsxv03x1";
+  };
+
+  postPatch = ''
+    cp -R --no-preserve=mode ${desmume} __build_desmume
+  '';
+
+  buildInputs = [ GitPython libpcap SDL2 alsaLib soundtouch openal ];
+  nativeBuildInputs = [ meson ninja pkg-config ];
+  propagatedBuildInputs = [ pillow pygobject3 ];
+
+  hardeningDisable = [ "format" ];
+
+  doCheck = false; # there are no tests
+  pythonImportsCheck = [ "desmume" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/SkyTemple/py-desmume";
+    description = "Python library to interface with DeSmuME, the Nintendo DS emulator";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ xfix ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -5603,6 +5603,8 @@ in {
 
   pydenticon = callPackage ../development/python-modules/pydenticon { };
 
+  py-desmume = callPackage ../development/python-modules/py-desmume { };
+
   pydexcom = callPackage ../development/python-modules/pydexcom { };
 
   pydicom = callPackage ../development/python-modules/pydicom { };