Merge pull request #49138 from fuwa0529/add-wownero

wownero: init at 0.4.0.0

maintainers/maintainer-list.nix

@@ -1536,6 +1536,11 @@
     github = "fuuzetsu";
     name = "Mateusz Kowalczyk";
   };
+  fuwa = {
+    email = "echowss@gmail.com";
+    github = "fuwa0529";
+    name = "Haruka Akiyama";
+  };
   fuzzy-id = {
     email = "hacking+nixos@babibo.de";
     name = "Thomas Bach";

pkgs/applications/altcoins/default.nix

@@ -81,6 +81,10 @@ rec {
 
   sumokoin = callPackage ./sumokoin.nix { };
 
+  wownero = callPackage ./wownero.nix {
+    inherit (darwin.apple_sdk.frameworks) CoreData IOKit PCSC;
+  };
+
   zcash = callPackage ./zcash {
     withGui = false;
     openssl = openssl_1_1;

pkgs/applications/altcoins/wownero.nix

@@ -0,0 +1,51 @@
+{ stdenv, fetchFromGitHub, cmake, pkgconfig, git
+, boost, miniupnpc, openssl, unbound, cppzmq
+, zeromq, pcsclite, readline, libsodium
+, CoreData, IOKit, PCSC
+}:
+
+assert stdenv.isDarwin -> IOKit != null;
+
+with stdenv.lib;
+
+stdenv.mkDerivation rec {
+  name = "wownero-${version}";
+
+  version = "0.4.0.0";
+  src = fetchFromGitHub {
+    owner = "wownero";
+    repo = "wownero";
+    fetchSubmodules = true;
+    rev    = "v${version}";
+    sha256 = "1z5fpl4gwys4v8ffrymlzwrbnrbg73x553a9lxwny7ba8yg2k14p";
+  };
+
+  nativeBuildInputs = [ cmake pkgconfig git ];
+
+  buildInputs = [
+    boost miniupnpc openssl unbound
+    cppzmq zeromq pcsclite readline libsodium
+  ] ++ optionals stdenv.isDarwin [ IOKit CoreData PCSC ];
+
+  cmakeFlags = [
+    "-DReadline_ROOT_DIR=${readline.dev}"
+    "-DMANUAL_SUBMODULES=ON"
+  ] ++ optional stdenv.isDarwin "-DBoost_USE_MULTITHREADED=OFF";
+
+  hardeningDisable = [ "fortify" ];
+
+  meta = {
+    description = "Wownero is a fork of the cryptocurrency Monero with primary alterations";
+    longDescription = ''
+      Wownero’s emission is capped and supply is finite. Wownero is a fairly
+      launched coin with no premine. It’s not a fork of another blockchain. With
+      its own genesis block there is no degradation of privacy caused by ring
+      signatures using different participants for the same transaction outputs.
+      Unlike opposing forks.
+    '';
+    homepage    = http://wownero.org/;
+    license     = licenses.bsd3;
+    platforms   = platforms.all;
+    maintainers = with maintainers; [ fuwa ];
+  };
+}