granian: init at 1.5.2

pkgs/by-name/gr/granian/package.nix

@@ -0,0 +1,50 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  python3Packages,
+  libiconv,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "granian";
+  version = "1.5.2";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "emmett-framework";
+    repo = "granian";
+    rev = "v${version}";
+    hash = "sha256-3kwdPLOkKKSY1w42av3ejarrRKNtai8KB80ZrujSjPo=";
+  };
+
+  cargoDeps = rustPlatform.importCargoLock {
+    lockFile = ./Cargo.lock;
+    outputHashes = {
+      "pyo3-log-0.11.0" = "sha256-UU8064vM7cf20lwfifyPC205CY4tIgif0slDz/Pjf9Q=";
+    };
+  };
+
+  nativeBuildInputs = with rustPlatform; [
+    cargoSetupHook
+    maturinBuildHook
+  ];
+
+  buildInputs = [
+    libiconv
+  ];
+
+  dependencies = [
+    python3Packages.uvloop
+    python3Packages.click
+  ];
+
+  meta = {
+    description = "Rust HTTP server for Python ASGI/WSGI/RSGI applications";
+    homepage = "https://github.com/emmett-framework/granian";
+    license = lib.licenses.bsd3;
+    mainProgram = "granian";
+    maintainers = with lib.maintainers; [ lucastso10 ];
+    platforms = lib.platforms.unix;
+  };
+}