Merge pull request #44954 from markuskowa/qradiolink

qradiolink: init at 0.5.0

pkgs/applications/misc/qradiolink/default.nix

@@ -0,0 +1,57 @@
+{ stdenv, fetchFromGitHub, alsaLib, boost
+, qt4, libpulseaudio, codec2, libconfig
+, gnuradio, gnuradio-osmosdr, gsm
+, libopus, libjpeg, protobuf, qwt, speex
+} :
+
+let
+  version = "0.5.0";
+
+in stdenv.mkDerivation {
+  name = "qradiolink-${version}";
+
+  src = fetchFromGitHub {
+    owner = "kantooon";
+    repo = "qradiolink";
+    rev = "${version}";
+    sha256 = "0xhg5zhjznmls5m3rhpk1qx0dipxmca12s85w15d0i7qwva2f1gi";
+  };
+
+  preBuild = ''
+    cd ext
+    protoc --cpp_out=. Mumble.proto
+    protoc --cpp_out=. QRadioLink.proto
+    cd ..
+    qmake
+  '';
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp qradiolink $out/bin
+  '';
+
+  buildInputs = [
+    qt4
+    alsaLib
+    boost
+    libpulseaudio
+    codec2
+    libconfig
+    gsm
+    gnuradio
+    gnuradio-osmosdr
+    libopus
+    libjpeg
+    protobuf
+    speex
+    qwt
+  ];
+
+  meta = with stdenv.lib; {
+    description = "SDR transceiver application for analog and digital modes";
+    homepage = http://qradiolink.org/;
+    license = licenses.agpl3;
+    maintainers = [ maintainers.markuskowa ];
+    platforms = platforms.linux;
+  };
+}

pkgs/development/libraries/codec2/default.nix

@@ -0,0 +1,25 @@
+{ stdenv, fetchsvn, cmake } :
+
+let
+  version = "0.8";
+
+in stdenv.mkDerivation {
+  name = "codec2-${version}";
+
+  src = fetchsvn {
+    url = "https://svn.code.sf.net/p/freetel/code/codec2/branches/${version}";
+    sha256 = "0qbyaqdn37253s30n6m2ric8nfdsxhkslb9h572kdx18j2yjccki";
+  };
+
+  enableParallelBuilding = true;
+
+  nativeBuildInputs = [ cmake ];
+
+  meta = with stdenv.lib; {
+    description = "Speech codec designed for communications quality speech at low data rates";
+    homepage = http://www.rowetel.com/blog/?page_id=452;
+    license = licenses.lgpl21;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ markuskowa ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -1121,6 +1121,8 @@ with pkgs;
 
   codesearch = callPackage ../tools/text/codesearch { };
 
+  codec2 = callPackage ../development/libraries/codec2 { };
+
   contacts = callPackage ../tools/misc/contacts {
     inherit (darwin.apple_sdk.frameworks) Foundation AddressBook;
   };
@@ -11756,6 +11758,8 @@ with pkgs;
 
   lvtk = callPackage ../development/libraries/audio/lvtk { };
 
+  qradiolink = callPackage ../applications/misc/qradiolink { };
+
   qrupdate = callPackage ../development/libraries/qrupdate { };
 
   resolv_wrapper = callPackage ../development/libraries/resolv_wrapper { };