From a98de94a13bd19dfa4a10d64504f66632e2bc1de Mon Sep 17 00:00:00 2001
From: Alkeryn <plbraundev@gmail.com>
Date: Sun, 25 Aug 2019 14:20:02 +0200
Subject: [PATCH] sdrangel: init at 4.11.7

---
 pkgs/applications/radio/sdrangel/default.nix | 74 ++++++++++++++++++++
 pkgs/top-level/all-packages.nix              |  2 +
 2 files changed, 76 insertions(+)
 create mode 100644 pkgs/applications/radio/sdrangel/default.nix

diff --git a/pkgs/applications/radio/sdrangel/default.nix b/pkgs/applications/radio/sdrangel/default.nix
new file mode 100644
index 000000000000..63e36fc9143c
--- /dev/null
+++ b/pkgs/applications/radio/sdrangel/default.nix
@@ -0,0 +1,74 @@
+{
+boost,
+cm256cc,
+cmake,
+codec2,
+fetchFromGitHub,
+fftwFloat,
+glew,
+lib,
+libav,
+libiio,
+libopus,
+libpulseaudio,
+libusb,
+limesuite,
+mkDerivation,
+ocl-icd,
+opencv3,
+pkgconfig,
+qtbase,
+qtmultimedia,
+qtwebsockets,
+serialdv
+}:
+
+let
+
+  codec2' = codec2.overrideAttrs (old: {
+    src = fetchFromGitHub {
+      owner = "drowe67";
+      repo = "codec2";
+      rev = "567346818c0d4d697773cf66d925fdb031e15668";
+      sha256 = "0ngqlh2cw5grx2lg7xj8baz6p55gfhq4caggxkb4pxlg817pwbpa";
+    };
+  });
+
+in mkDerivation rec {
+  pname = "sdrangel";
+  version = "4.11.7";
+
+  src = fetchFromGitHub {
+    owner = "f4exb";
+    repo = "sdrangel";
+    rev = "v${version}";
+    sha256 = "0zbx0gklylk8npb3wnnmqpam0pdxl40f20i3wzwwh4gqrppxywzx";
+    fetchSubmodules = false;
+  };
+
+  nativeBuildInputs = [ cmake pkgconfig ];
+  buildInputs = [
+    glew opencv3 libusb boost libopus limesuite libav libiio libpulseaudio
+    qtbase qtwebsockets qtmultimedia
+    fftwFloat
+    codec2' cm256cc serialdv
+  ];
+  cmakeFlags = [
+    "-DLIBSERIALDV_INCLUDE_DIR:PATH=${serialdv}/include/serialdv"
+    "-DLIMESUITE_INCLUDE_DIR:PATH=${limesuite}/include"
+    "-DLIMESUITE_LIBRARY:FILEPATH=${limesuite}/lib/libLimeSuite.so"
+  ];
+
+  LD_LIBRARY_PATH = "${ocl-icd}/lib";
+
+  meta = with lib; {
+    description = "Software defined radio (SDR) software";
+    longDescription = ''
+        SDRangel is an Open Source Qt5 / OpenGL 3.0+ SDR and signal analyzer frontend to various hardware.
+    '';
+    homepage = "https://github.com/f4exb/sdrangel";
+    license = licenses.gpl3Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ alkeryn ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index f127381be221..5b7f43ee7036 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -16330,6 +16330,8 @@ in
 
   sdparm = callPackage ../os-specific/linux/sdparm { };
 
+  sdrangel = libsForQt5.callPackage ../applications/radio/sdrangel {  };
+
   sepolgen = callPackage ../os-specific/linux/sepolgen { };
 
   setools = callPackage ../os-specific/linux/setools { };