Merge pull request #98972 from JustinLovinger/rofimoji

rofimoji: init at 4.3.0, wtype: init at 2020-09-14

maintainers/maintainer-list.nix

@@ -4262,6 +4262,12 @@
     githubId = 39434424;
     name = "Felix Springer";
   };
+  justinlovinger = {
+    email = "git@justinlovinger.com";
+    github = "JustinLovinger";
+    githubID = 7183441;
+    name = "Justin Lovinger";
+  };
   justinwoo = {
     email = "moomoowoo@gmail.com";
     github = "justinwoo";

pkgs/applications/misc/rofimoji/default.nix

@@ -0,0 +1,45 @@
+{ buildPythonApplication
+, fetchFromGitHub
+, lib
+
+, waylandSupport ? true
+, x11Support ? true
+
+, ConfigArgParse
+, pyxdg
+, rofi
+, wl-clipboard
+, wtype
+, xdotool
+, xsel
+}:
+
+buildPythonApplication rec {
+  pname = "rofimoji";
+  version = "4.3.0";
+
+  src = fetchFromGitHub {
+    owner = "fdw";
+    repo = "rofimoji";
+    rev = version;
+    sha256 = "08ayndpifr04njpijc5n5ii5nvibfpab39p6ngyyj0pb43792a8j";
+  };
+
+  # `rofi` and the `waylandSupport` and `x11Support` dependencies
+  # contain binaries needed at runtime.
+  propagatedBuildInputs = with lib; [ ConfigArgParse pyxdg rofi ]
+    ++ optionals waylandSupport [ wl-clipboard wtype ]
+    ++ optionals x11Support [ xdotool xsel ];
+
+  # The 'extractors' sub-module is used for development
+  # and has additional dependencies.
+  postPatch = "rm -rf extractors";
+
+  meta = with lib; {
+    description = "A simple emoji and character picker for rofi";
+    homepage = "https://github.com/fdw/rofimoji";
+    license = licenses.mit;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ justinlovinger ];
+  };
+}

pkgs/tools/wayland/wtype/default.nix

@@ -0,0 +1,34 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+
+, meson
+, ninja
+, pkg-config
+
+, libxkbcommon
+, wayland
+}:
+
+stdenv.mkDerivation {
+  pname = "wtype";
+  version = "2020-09-14";
+
+  src = fetchFromGitHub {
+    owner = "atx";
+    repo = "wtype";
+    rev = "74071228dea4047157ae82960a2541ecc431e4a1";
+    sha256 = "1ncspxpnbwv1vkfmxs58q7aykjb6skaa1pg5sw5h798pss5j80rd";
+  };
+
+  nativeBuildInputs = [ meson ninja pkg-config wayland ];
+  buildInputs = [ libxkbcommon wayland ];
+
+  meta = with lib; {
+    description = "xdotool type for wayland";
+    homepage = "https://github.com/atx/wtype";
+    license = licenses.mit;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ justinlovinger ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -3406,6 +3406,8 @@ in
 
   wob = callPackage ../tools/misc/wob { };
 
+  wtype = callPackage ../tools/wayland/wtype { };
+
   wrangler = callPackage ../development/tools/wrangler { };
 
   xkcdpass = with pythonPackages; toPythonApplication xkcdpass;
@@ -23075,6 +23077,10 @@ in
 
   rofi-systemd = callPackage ../tools/system/rofi-systemd { };
 
+  rofimoji = callPackage ../applications/misc/rofimoji {
+    inherit (python3Packages) buildPythonApplication ConfigArgParse pyxdg;
+  };
+
   rootlesskit = callPackage ../tools/virtualization/rootlesskit {};
 
   rpcs3 = libsForQt514.callPackage ../misc/emulators/rpcs3 { };