From 969a23fa50d5a92c440beaff1a5d023e5249155f Mon Sep 17 00:00:00 2001
From: Tadeo Kondrak <me@tadeo.ca>
Date: Tue, 25 Jun 2019 16:53:32 -0600
Subject: [PATCH] vapoursynth-editor: init at R19

---
 .../libraries/vapoursynth/editor.nix          | 41 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 43 insertions(+)
 create mode 100644 pkgs/development/libraries/vapoursynth/editor.nix

diff --git a/pkgs/development/libraries/vapoursynth/editor.nix b/pkgs/development/libraries/vapoursynth/editor.nix
new file mode 100644
index 000000000000..3853718c1541
--- /dev/null
+++ b/pkgs/development/libraries/vapoursynth/editor.nix
@@ -0,0 +1,41 @@
+{ stdenv, fetchFromBitbucket, makeWrapper
+, python3, vapoursynth
+, qmake, qtbase, qtwebsockets
+}:
+
+stdenv.mkDerivation rec {
+  pname = "vapoursynth-editor";
+  version = "R19";
+
+  src = fetchFromBitbucket {
+    owner = "mystery_keeper";
+    repo = pname;
+    rev = stdenv.lib.toLower version;
+    sha256 = "1zlaynkkvizf128ln50yvzz3b764f5a0yryp6993s9fkwa7djb6n";
+  };
+
+  nativeBuildInputs = [ qmake makeWrapper ];
+  buildInputs = [ qtbase vapoursynth qtwebsockets ];
+
+  preConfigure = "cd pro";
+
+  installPhase = ''
+    cd ../build/release*
+    mkdir -p $out/bin
+    for bin in vsedit{,-job-server{,-watcher}}; do
+        mv $bin $out/bin
+
+        wrapProgram $out/bin/$bin \
+            --prefix PYTHONPATH : ${vapoursynth}/${python3.sitePackages} \
+            --prefix LD_LIBRARY_PATH : ${vapoursynth}/lib
+    done
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Cross-platform editor for VapourSynth scripts";
+    homepage = "https://bitbucket.org/mystery_keeper/vapoursynth-editor";
+    license = licenses.mit;
+    maintainers = with maintainers; [ tadeokondrak ];
+    platforms = platforms.all;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 9b4ede9c53bf..55cafcb8c1ba 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -22059,6 +22059,8 @@ in
     inherit (darwin.apple_sdk.frameworks) ApplicationServices;
   };
 
+  vapoursynth-editor = libsForQt5.callPackage ../development/libraries/vapoursynth/editor.nix { };
+
   vapoursynth-mvtools = callPackage ../development/libraries/vapoursynth-mvtools { };
 
   vassal = callPackage ../games/vassal { };