sky: init at 2.1.7801

pkgs/applications/networking/instant-messengers/sky/default.nix

@@ -0,0 +1,66 @@
+{ lib
+, mkDerivation
+, fetchurl
+, autoPatchelfHook
+, zstd
+, curl
+, ffmpeg
+, libjpeg_turbo
+, libpam-wrapper
+, libv4l
+, pulseaudio
+, zlib
+, xorg
+}:
+
+mkDerivation rec {
+  pname = "sky";
+  version = "2.1.7801";
+
+  src = fetchurl {
+    url = "https://tel.red/repos/archlinux/sky-archlinux-${version}-1-x86_64.pkg.tar.zst";
+    sha256 = "sha256-3xiq2b3CwNjRd09q0z8olrmLGhgkJGAVkZoJSIHom+k=";
+  };
+
+  nativeBuildInputs = [ autoPatchelfHook zstd ];
+
+  buildInputs = [
+    curl
+    ffmpeg
+    libjpeg_turbo
+    libpam-wrapper
+    libv4l
+    pulseaudio
+    xorg.libX11
+    xorg.libXScrnSaver
+    xorg.libXcursor
+    xorg.libXdamage
+    xorg.libXinerama
+    xorg.libXmu
+    xorg.libXrandr
+    xorg.libXtst
+    xorg.libXv
+    xorg.libxkbfile
+    zlib
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir $out
+    mv * $out/
+    ln --force --symbolic $out/lib/sky/sky{,_sender} $out/bin
+    substituteInPlace $out/share/applications/sky.desktop \
+      --replace /usr/ $out/
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Lync & Skype for Business on Linux";
+    homepage = "https://tel.red/";
+    license = lib.licenses.unfree;
+    maintainers = [ lib.maintainers.wucke13 ];
+    platforms = [ "x86_64-linux" ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -28688,6 +28688,10 @@ with pkgs;
 
   sish = callPackage ../tools/networking/sish { };
 
+  sky = libsForQt5.callPackage ../applications/networking/instant-messengers/sky {
+    libjpeg_turbo = libjpeg_turbo.override { enableJpeg8 = true; };
+  };
+
   skypeforlinux = callPackage ../applications/networking/instant-messengers/skypeforlinux { };
 
   SkypeExport = callPackage ../applications/networking/instant-messengers/SkypeExport { };