Merge pull request #35668 from lsix/add_pythonPackages_kubernetes

pythonPackages.kubernetes: init at 5.0.0

pkgs/development/python-modules/kubernetes/default.nix

@@ -0,0 +1,38 @@
+{ stdenv, buildPythonPackage, fetchPypi, pythonAtLeast,
+  ipaddress, websocket_client, urllib3, pyyaml, requests_oauthlib, python-dateutil, google_auth,
+  isort, pytest, coverage, mock, sphinx, autopep8, pep8, codecov, recommonmark, nose }:
+
+buildPythonPackage rec {
+  pname = "kubernetes";
+  version = "5.0.0";
+
+  prePatch = ''
+    sed -e 's/sphinx>=1.2.1,!=1.3b1,<1.4 # BSD/sphinx/' -i test-requirements.txt
+
+    # This is used to randomize tests, which is not reproducible. Drop it.
+    sed -e '/randomize/d' -i test-requirements.txt
+  ''
+  # This is a python2 and python3.2 only requiremet since it is a backport of a python-3.3 api.
+  + (if (pythonAtLeast "3.3")  then ''
+    sed -e '/ipaddress/d' -i requirements.txt
+  '' else "");
+
+  checkPhase = ''
+    py.test
+  '';
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "1z8rrlq73bzli9rg57kj8ivz09vhsydyjq1ksbcis6j7h9c187zq";
+  };
+
+  checkInputs = [ isort coverage pytest mock sphinx autopep8 pep8 codecov recommonmark nose ];
+  propagatedBuildInputs = [ ipaddress websocket_client urllib3 pyyaml requests_oauthlib python-dateutil google_auth ];
+
+  meta = with stdenv.lib; {
+    description = "Kubernetes python client";
+    homepage = https://github.com/kubernetes-client/python;
+    license = licenses.asl20;
+    maintainers = with maintainers; [ lsix ];
+  };
+}

pkgs/development/python-modules/websockets_client/default.nix

@@ -0,0 +1,24 @@
+{ stdenv, buildPythonPackage, fetchPypi, six }:
+buildPythonPackage rec {
+  pname = "websocket_client";
+  version = "0.47.0";
+
+  src = fetchPypi {
+    inherit version pname;
+    sha256 = "0jb1446053ryp5p25wsr1hjfdzwfm04a6f3pzpcb63bfz96xqlx4";
+  };
+
+  prePatch = ''
+    # ssl.match_hostname exists in python2.7 version maintained in nixpkgs,
+    # the dependency is not necessary.
+    sed -e "s/\['backports.ssl_match_hostname'\]/\[\]/" -i setup.py
+  '';
+
+  propagatedBuildInputs = [ six ];
+
+  meta = with stdenv.lib; {
+    homepage = https://github.com/liris/websocket-client;
+    description = "Websocket client for python";
+    license = licenses.lgpl2;
+  };
+}

pkgs/top-level/python-packages.nix

@@ -9268,6 +9268,8 @@ in {
 
   kitchen = callPackage ../development/python-modules/kitchen/default.nix { };
 
+  kubernetes = callPackage ../development/python-modules/kubernetes/default.nix { };
+
   pylast = callPackage ../development/python-modules/pylast/default.nix { };
 
   pylru = callPackage ../development/python-modules/pylru/default.nix { };
@@ -18683,22 +18685,7 @@ EOF
   };
 
 
-  websocket_client = buildPythonPackage rec {
-    name = "websocket_client-0.40.0";
-
-    src = pkgs.fetchurl {
-      url = "mirror://pypi/w/websocket-client/${name}.tar.gz";
-      sha256 = "1yz67wdjijrvwpx0a0f6wdfy8ajsvr9xbj5514ld452fqnh19b20";
-    };
-
-    propagatedBuildInputs = with self; [ six backports_ssl_match_hostname unittest2 argparse ];
-
-    meta = {
-      homepage = https://github.com/liris/websocket-client;
-      description = "Websocket client for python";
-      license = licenses.lgpl2;
-    };
-  };
+  websocket_client = callPackage ../development/python-modules/websockets_client { };
 
 
   webhelpers = buildPythonPackage rec {