From 5d88b73cef172c2ea5879b84740d9f2f4881185c Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Edward=20Tj=C3=B6rnhammar?= <ed@cflags.cc>
Date: Thu, 25 May 2017 17:33:19 +0200
Subject: [PATCH] feedreader: init at 2.2

---
 .../feedreaders/feedreader/default.nix        | 50 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 52 insertions(+)
 create mode 100644 pkgs/applications/networking/feedreaders/feedreader/default.nix

diff --git a/pkgs/applications/networking/feedreaders/feedreader/default.nix b/pkgs/applications/networking/feedreaders/feedreader/default.nix
new file mode 100644
index 000000000000..505afd25d04f
--- /dev/null
+++ b/pkgs/applications/networking/feedreaders/feedreader/default.nix
@@ -0,0 +1,50 @@
+{ stdenv, fetchFromGitHub, meson, ninja, pkgconfig, vala_0_40, gettext
+, appstream-glib, desktop-file-utils, glibcLocales, wrapGAppsHook
+, curl, glib, gnome3, gst_all_1, json-glib, libnotify, libsecret, sqlite
+}:
+
+let
+  pname = "FeedReader";
+  version = "2.2";
+in stdenv.mkDerivation {
+  name = "${pname}-${version}";
+
+  src = fetchFromGitHub {
+    owner = "jangernert";
+    repo = pname;
+    rev = "v" + version;
+    sha256 = "17588hsa7xv92ba55kmbyvnijypp373yrly48kbc391wadp1z939";
+  };
+
+  nativeBuildInputs = [
+    meson ninja pkgconfig vala_0_40 gettext appstream-glib desktop-file-utils
+    glibcLocales wrapGAppsHook
+  ];
+
+  buildInputs = [
+    curl glib json-glib libnotify libsecret sqlite
+  ] ++ (with gnome3; [
+    gtk libgee libpeas libsoup rest webkitgtk gnome_online_accounts
+    gsettings_desktop_schemas
+  ]) ++ (with gst_all_1; [
+    gstreamer gst-plugins-base gst-plugins-good
+  ]);
+
+  # TODO: fix https://github.com/NixOS/nixpkgs/issues/39547
+  LIBRARY_PATH = stdenv.lib.makeLibraryPath [ curl ];
+
+  # vcs_tag function fails with UnicodeDecodeError
+  LC_ALL = "en_US.UTF-8";
+
+  postPatch = ''
+    patchShebangs meson_post_install.py
+  '';
+
+  meta = with stdenv.lib; {
+    description = "A modern desktop application designed to complement existing web-based RSS accounts.";
+    homepage = https://jangernert.github.io/FeedReader/;
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ edwtjo ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index d2b566ab5f62..5b854870d298 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -2311,6 +2311,8 @@ with pkgs;
 
   fdm = callPackage ../tools/networking/fdm {};
 
+  feedreader = callPackage ../applications/networking/feedreaders/feedreader {};
+
   ferm = callPackage ../tools/networking/ferm { };
 
   fgallery = callPackage ../tools/graphics/fgallery {