linux/manual-config: Change from 'features' to 'config' and fix build when firmware is installed.

Instead of manually adding which 'features' a kernel has based on its config here, just generate a nixexpr representation of the whole config and let places that need it (e.g. NixOS modules) decide how to map config options to features.

Note that if your kernel requires firmware whose hex file sits directly in ${src}/firmware rather than in a subdirectory thereof, you may need this patch for now: https://lkml.org/lkml/2012/7/31/724

pkgs/os-specific/linux/kernel/manual-config.nix

@@ -4,26 +4,41 @@ with stdenv.lib;
 
 let
 
-  # Function to parse the config file to get the features supported
+  # Function to parse the config file into a nix expression
-  readFeatures = config:
+  readConfig = configFile:
     let
-      configAttrs = import "${runCommand "attrList.nix" {} ''
+      configAttrs = import "${runCommand "config.nix" {} ''
-        grep -E -v '(^#|^$)' < ${config} | \
+        (. ${configFile}
-          sed 's/CONFIG_// ; s/=/ /' | \
+        echo "{"
-          awk \
+        for var in `set`; do
-            'BEGIN { print "{" }
+            if [[ "$var" =~ ^CONFIG_ ]]; then
-             END { print "}" }
+                IFS="="
-             { printf "\"%s\" = '"'''"'%s'"'''"';\n", $1, $2 }' > $out
+                set -- $var
+                echo "\"$1\" = \"''${*:2}\";"
+            fi
+        done
+        echo "}") > $out
       ''}";
-      getValue = option:
-        if hasAttr option configAttrs then getAttr option configAttrs else null;
 
-      isYes = option: (getValue option) == "y";
+      config = configAttrs // rec {
+        attrName = attr: "CONFIG_" + attr;
+
+        isSet = attr: hasAttr (attrName attr) config;
+
+        getValue = attr: if isSet attr then getAttr (attrName attr) config else null;
+
+        isYes = attr: (isSet attr) && ((getValue attr) == "y");
+
+        isNo = attr: (isSet attr) && ((getValue attr) == "n");
+
+        isModule = attr: (isSet attr) && ((getValue attr) == "m");
+
+        isEnabled = attr: (isModule attr) || (isYes attr);
+
+        isDisabled = attr: (!(isSet attr)) || (isNo attr);
+      };
     in
-
+      config;
-    {
-      modular = isYes "MODULES";
-    };
 
 in
 
@@ -37,36 +52,35 @@ in
   # Any patches
   patches ? [],
   # The kernel .config file
-  config,
+  configfile,
-  # Manually specified features the kernel supports
+  # Manually specified nixexpr representing the config
   # If unspecified, this will be autodetected from the .config
-  features ? optionalAttrs allowImportFromDerivation (readFeatures config),
+  config ? optionalAttrs allowImportFromDerivation (readConfig configfile),
   # Whether to utilize the controversial import-from-derivation feature to parse the config
   allowImportFromDerivation ? false
 }:
 
 let
-  commonMakeFlags = [
-    "O=../build"
-    "INSTALL_PATH=$(out)"
-    "INSTALLKERNEL=${installkernel}"
-  ];
-
   installkernel = writeTextFile { name = "installkernel"; executable=true; text = ''
     #!/bin/sh
     mkdir $4
     mv -v $2 $4
     mv -v $3 $4
   '';};
+
+  isModular = config.isYes "MODULES";
+
+  installsFirmware = (config.isEnabled "FW_LOADER") &&
+    (isModular || (config.isNo "FIRMWARE_IN_KERNEL"));
 in
 
-stdenv.mkDerivation ({
+stdenv.mkDerivation {
   name = "linux-${version}";
 
   enableParallelBuilding = true;
 
   passthru = {
-    inherit version modDirVersion features;
+    inherit version modDirVersion config;
   };
 
   inherit patches src;
@@ -82,15 +96,40 @@ stdenv.mkDerivation ({
     runHook preConfigure
     mkdir ../build
     make $makeFlags "''${makeFlagsArray[@]}" mrproper
-    ln -sv ${config} ../build/.config
+    ln -sv ${configfile} ../build/.config
     make $makeFlags "''${makeFlagsArray[@]}" oldconfig
     rm ../build/.config.old
     runHook postConfigure
   '';
 
-  buildNativeInputs = [ perl nettools kmod ];
+  buildNativeInputs = [ perl nettools ] ++ optional isModular kmod;
 
-  makeFlags = commonMakeFlags;
+  makeFlags = [
+    "O=../build"
+    "INSTALL_PATH=$(out)"
+    "INSTALLKERNEL=${installkernel}"
+  ] ++ (optional isModular "MODLIB=\"$(out)/lib/modules/${modDirVersion}\"")
+  ++ optional installsFirmware "INSTALL_FW_PATH=\"$(out)/lib/firmware\"";
+
+  postInstall = if isModular then ''
+    make modules_install $makeFlags "''${makeFlagsArray[@]}" \
+      $installFlags "''${installFlagsArray[@]}"
+    rm -f $out/lib/modules/${modDirVersion}/{build,source}
+    cd ..
+    mv $sourceRoot $out/lib/modules/${modDirVersion}/source
+    mv build $out/lib/modules/${modDirVersion}/build
+    unlink $out/lib/modules/${modDirVersion}/build/source
+    ln -sv $out/lib/modules/${modDirVersion}/{,build/}source
+  '' else optionalString installsFirmware ''
+    make firmware_install $makeFlags "''${makeFlagsArray[@]}" \
+      $installFlags "''${installFlagsArray[@]}"
+  '';
+
+  postFixup = optionalString isModular ''
+    if [ -z "$dontStrip" ]; then
+        find $out -name "*.ko" -print0 | xargs -0 strip -S
+    fi
+  '';
 
   meta = {
     description = "The Linux kernel";
@@ -101,25 +140,4 @@ stdenv.mkDerivation ({
     ];
     platforms = lib.platforms.linux;
   };
-} // optionalAttrs (features ? modular && features.modular) {
+}
-  makeFlags = commonMakeFlags ++ [
-    "MODLIB=\"$(out)/lib/modules/${modDirVersion}\""
-  ];
-
-  postInstall = ''
-    make modules_install $makeFlags "''${makeFlagsArray[@]}" \
-      $installFlags "''${installFlagsArray[@]}"
-    rm -f $out/lib/modules/${modDirVersion}/{build,source}
-    cd ..
-    mv $sourceRoot $out/lib/modules/${modDirVersion}/source
-    mv build $out/lib/modules/${modDirVersion}/build
-    unlink $out/lib/modules/${modDirVersion}/build/source
-    ln -sv $out/lib/modules/${modDirVersion}/{,build/}source
-  '';
-
-  postFixup = ''
-    if [ -z "$dontStrip" ]; then
-        find $out -name "*.ko" -print0 | xargs -0 strip -S
-    fi
-  '';
-})