Merge pull request #3253 from bjornfor/gnome-boxes

Add Gnome Boxes (access remote or virtual systems)

pkgs/desktops/gnome-3/3.12/apps/gnome-boxes/default.nix

@@ -0,0 +1,47 @@
+{ stdenv, fetchurl, makeWrapper, pkgconfig, intltool, itstool, libvirt-glib
+, glib, gobjectIntrospection, libxml2, gtk3, gtkvnc, libvirt, spice_gtk
+, spice_protocol, libuuid, libsoup, libosinfo, systemd, tracker, vala
+, libcap_ng, libcap, yajl, gmp, gdbm, cyrus_sasl, gnome3, librsvg
+, hicolor_icon_theme, desktop_file_utils, mtools, cdrkit, libcdio
+}:
+
+# TODO: ovirt (optional)
+
+stdenv.mkDerivation rec {
+  name = "gnome-boxes-3.12.2";
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/gnome-boxes/3.12/${name}.tar.xz";
+    sha256 = "0kzdh8kk9isaskbfyj7r7nybgdyhj7i4idkgahdsl9xs9sj2pmc8";
+  };
+
+  enableParallelBuilding = true;
+
+  doCheck = true;
+
+  buildInputs = [
+    makeWrapper pkgconfig intltool itstool libvirt-glib glib
+    gobjectIntrospection libxml2 gtk3 gtkvnc libvirt spice_gtk spice_protocol
+    libuuid libsoup libosinfo systemd tracker vala libcap_ng libcap yajl gmp
+    gdbm cyrus_sasl gnome3.gnome_icon_theme gnome3.gnome_icon_theme_symbolic
+    librsvg hicolor_icon_theme desktop_file_utils
+  ];
+
+  preFixup = ''
+    for prog in "$out/bin/"*; do
+        wrapProgram "$prog" \
+            --set GDK_PIXBUF_MODULE_FILE "$GDK_PIXBUF_MODULE_FILE" \
+            --prefix XDG_DATA_DIRS : "${gnome3.gnome_themes_standard}/share:$XDG_ICON_DIRS:$GSETTINGS_SCHEMAS_PATH" \
+            --prefix PATH : "${mtools}/bin:${cdrkit}/bin:${libcdio}/bin"
+    done
+    rm "$out/share/icons/hicolor/icon-theme.cache"
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Simple GNOME 3 application to access remote or virtual systems";
+    homepage = https://wiki.gnome.org/action/show/Apps/Boxes;
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ bjornfor ];
+  };
+}

pkgs/desktops/gnome-3/3.12/default.nix

@@ -195,6 +195,11 @@ rec {
 
   glade = callPackage ./apps/glade { };
 
+  gnome-boxes = callPackage ./apps/gnome-boxes {
+    gtkvnc = pkgs.gtkvnc.override { enableGTK3 = true; };
+    spice_gtk = pkgs.spice_gtk.override { enableGTK3 = true; };
+  };
+
   gnome-clocks = callPackage ./apps/gnome-clocks { };
 
   gnome-documents = callPackage ./apps/gnome-documents { };

pkgs/development/libraries/libosinfo/default.nix

@@ -0,0 +1,24 @@
+{ stdenv, fetchurl, pkgconfig, intltool, gobjectIntrospection, libsoup
+, libxslt, check, vala ? null
+}:
+
+stdenv.mkDerivation rec {
+  name = "libosinfo-0.2.10";
+
+  src = fetchurl {
+    url = "https://fedorahosted.org/releases/l/i/libosinfo/${name}.tar.gz";
+    sha256 = "564bd487a39dc09a10917c1d7a95f739ee7701d9cd0fbabcacea64f615e20a2d";
+  };
+
+  buildInputs = [
+    pkgconfig intltool gobjectIntrospection libsoup libxslt check vala
+  ];
+
+  meta = with stdenv.lib; {
+    description = "Info about OSs, hypervisors and (virtual) hardware devices";
+    homepage = http://libosinfo.org/;
+    license = licenses.lgpl2Plus;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.bjornfor ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -5405,6 +5405,8 @@ let
 
   libopus = callPackage ../development/libraries/libopus { };
 
+  libosinfo = callPackage ../development/libraries/libosinfo {};
+
   libosip = callPackage ../development/libraries/osip {};
 
   libosip_3 = callPackage ../development/libraries/osip/3.nix {};