qtcurve: init at 1.9

pkgs/misc/themes/qtcurve/default.nix

@@ -0,0 +1,51 @@
+{ stdenv, fetchurl, cmake, extra-cmake-modules, pkgconfig
+, gtk2, qtbase, qtsvg, qtx11extras # Toolkit dependencies
+, karchive, kconfig, kconfigwidgets, kio, frameworkintegration
+, kguiaddons, ki18n, kwindowsystem, kdelibs4support, kiconthemes
+, libpthreadstubs, pcre, libXdmcp, libX11, libXau # X11 dependencies
+}:
+
+let
+  version = "1.9";
+in stdenv.mkDerivation {
+  name = "qtcurve-${version}";
+  src = fetchurl {
+    url = "http://download.kde.org/stable/qtcurve/qtcurve-${version}.tar.xz";
+    sha256 = "169gdny1cdld0qnx3nqvx568zjzdba4pwp3gxapc1hdh2cymw7r8";
+  };
+
+  enableParallelBuilding = true;
+
+  nativeBuildInputs = [ cmake extra-cmake-modules pkgconfig ];
+
+  buildInputs = [
+    gtk2
+    qtbase qtsvg qtx11extras
+    karchive kconfig kconfigwidgets kio kiconthemes kguiaddons ki18n
+    kwindowsystem kdelibs4support frameworkintegration
+    libpthreadstubs
+    pcre
+    libXdmcp libX11 libXau
+  ];
+
+  preConfigure = ''
+    for i in qt5/CMakeLists.txt qt5/config/CMakeLists.txt
+    do
+      substituteInPlace $i \
+        --replace "{_Qt5_PLUGIN_INSTALL_DIR}" "{KDE_INSTALL_QTPLUGINDIR}"
+    done
+    substituteInPlace CMakeLists.txt \
+      --replace \$\{GTK2_PREFIX\} $out
+    substituteInPlace gtk2/style/CMakeLists.txt \
+      --replace \$\{GTK2_LIBDIR\} $out/lib
+    patchShebangs tools/gen-version.sh
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = https://github.com/QtCurve/qtcurve;
+    description = "Widget styles for Qt5/Plasma 5 and gtk2";
+    platforms = platforms.linux;
+    license = licenses.lgpl21Plus;
+    maintainers = [ maintainers.gnidorah ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -18124,6 +18124,8 @@ with pkgs;
 
   ptex = callPackage ../development/libraries/ptex {};
 
+  qtcurve = libsForQt5.callPackage ../misc/themes/qtcurve {};
+
   rssguard = libsForQt5.callPackage ../applications/networking/feedreaders/rssguard { };
 
   scudcloud = callPackage ../applications/networking/instant-messengers/scudcloud { };