From 4d36c7a6c7fafe5916a154d9ca76bb9a8c417534 Mon Sep 17 00:00:00 2001
From: aleksana <me@aleksana.moe>
Date: Wed, 17 Jul 2024 00:02:46 +0800
Subject: [PATCH] nixtract: init at 0.3.0

---
 pkgs/by-name/ni/nixtract/package.nix | 60 ++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 pkgs/by-name/ni/nixtract/package.nix

diff --git a/pkgs/by-name/ni/nixtract/package.nix b/pkgs/by-name/ni/nixtract/package.nix
new file mode 100644
index 000000000000..e046e49d84f4
--- /dev/null
+++ b/pkgs/by-name/ni/nixtract/package.nix
@@ -0,0 +1,60 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  openssl,
+  stdenv,
+  libiconv,
+  darwin,
+  nix,
+  testers,
+  nixtract,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "nixtract";
+  version = "0.3.0";
+
+  src = fetchFromGitHub {
+    owner = "tweag";
+    repo = "nixtract";
+    rev = "v${version}";
+    hash = "sha256-36ciPNSlB1LU+UXP8MLakrBRRqbyiVFN8Jp/JbCe1OY=";
+  };
+
+  cargoHash = "sha256-fawBRIVcOhtDxxRYCf+HWYadoSB/ENKguTbS0M4odVU=";
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs =
+    [ openssl ]
+    ++ lib.optionals stdenv.isDarwin [
+      libiconv
+      darwin.apple_sdk.frameworks.SystemConfiguration
+    ];
+
+  nativeCheckInputs = [ nix ];
+
+  checkFlags = [
+    # Requiring network access
+    "--skip=nix::narinfo::tests::test_fetch"
+    "--skip=nix::substituters::tests::test_from_flake_ref"
+    # Requiring write to `/nix/var`
+    "--skip=nix::substituters::tests::test_get_substituters"
+    "--skip=tests::test_main_fixtures"
+  ];
+
+  passthru.tests.version = testers.testVersion { package = nixtract; };
+
+  meta = {
+    description = "CLI tool to extract the graph of derivations from a Nix flake";
+    homepage = "https://github.com/tweag/nixtract";
+    license = with lib.licenses; [
+      mit # or
+      asl20
+    ];
+    mainProgram = "nixtract";
+    maintainers = with lib.maintainers; [ aleksana ];
+  };
+}