From 2190a84812f33fbda2dc01edc6de1fb359a14dde Mon Sep 17 00:00:00 2001
From: Peter Hoeg <peter@speartail.com>
Date: Wed, 4 Jan 2017 16:37:45 +0800
Subject: [PATCH] tora: init at 3.1

---
 pkgs/development/tools/tora/default.nix | 67 +++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix         |  2 +
 2 files changed, 69 insertions(+)
 create mode 100644 pkgs/development/tools/tora/default.nix

diff --git a/pkgs/development/tools/tora/default.nix b/pkgs/development/tools/tora/default.nix
new file mode 100644
index 000000000000..9f8f2df358a5
--- /dev/null
+++ b/pkgs/development/tools/tora/default.nix
@@ -0,0 +1,67 @@
+{ stdenv, lib, fetchFromGitHub, cmake, ecm, makeQtWrapper
+, boost, doxygen, openssl, mysql, postgresql, graphviz, loki, qscintilla, qtbase }:
+
+let
+  qscintillaLib = (qscintilla.override { withQt5 = true; });
+
+in stdenv.mkDerivation rec {
+  name = "tora-${version}";
+  version = "3.1";
+
+  src = fetchFromGitHub {
+    owner  = "tora-tool";
+    repo   = "tora";
+    rev    = "v${version}";
+    sha256 = "0wninl10bcgiljf6wnhn2rv8kmzryw78x5qvbw8s2zfjlnxjsbn7";
+  };
+
+  enableParallelBuilding = true;
+
+  buildInputs = [
+    cmake ecm makeQtWrapper
+    boost doxygen graphviz loki mysql openssl postgresql qscintillaLib qtbase
+  ];
+
+  preConfigure = ''
+    sed -i \
+      's|defaultGvHome = "/usr/bin"|defaultGvHome = "${lib.getBin graphviz}/bin"|' \
+      src/widgets/toglobalsetting.cpp
+
+    sed -i \
+      's|/usr/bin/dot|${lib.getBin graphviz}/bin/dot|' \
+      extlibs/libermodel/dotgraph.cpp
+  '';
+
+  cmakeFlags = [
+    "-DWANT_INTERNAL_LOKI=0"
+    "-DWANT_INTERNAL_QSCINTILLA=0"
+    # cmake/modules/FindQScintilla.cmake looks in qtbase and for the wrong library name
+    "-DQSCINTILLA_INCLUDE_DIR=${qscintillaLib}/include"
+    "-DQSCINTILLA_LIBRARY=${qscintillaLib}/lib/libqscintilla2.so"
+    "-DENABLE_DB2=0"
+    "-DENABLE_ORACLE=0"
+    "-DENABLE_TERADATA=0"
+    "-DQT5_BUILD=1"
+    "-Wno-dev"
+  ];
+
+  # these libraries are only searched for at runtime so we need to force-link them
+  NIX_LDFLAGS = [
+    "-lgvc"
+    "-lmysqlclient"
+    "-lecpg"
+    "-lssl"
+  ];
+
+  postFixup = ''
+    wrapQtProgram $out/bin/tora \
+      --prefix PATH : ${lib.getBin graphviz}/bin
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Tora SQL tool";
+    maintainers = with maintainers; [ peterhoeg ];
+    platforms = platforms.linux;
+    license = licenses.asl20;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index ffd247412821..87dd399a980d 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -17932,6 +17932,8 @@ in
 
   zoom-us = qt55.callPackage ../applications/networking/instant-messengers/zoom-us {};
 
+  tora = qt5.callPackage ../development/tools/tora {};
+
   xulrunner = firefox-unwrapped;
 
   nitrokey-app = callPackage ../tools/security/nitrokey-app { };