From 1ae6b4c2ee29e020007fa263e8df99aeb4041bdd Mon Sep 17 00:00:00 2001
From: Christoph Neidahl <christoph.neidahl@gmail.com>
Date: Thu, 14 Jan 2021 12:38:33 +0100
Subject: [PATCH] megapixels: init at 0.14.0

---
 .../graphics/megapixels/default.nix           | 55 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 57 insertions(+)
 create mode 100644 pkgs/applications/graphics/megapixels/default.nix

diff --git a/pkgs/applications/graphics/megapixels/default.nix b/pkgs/applications/graphics/megapixels/default.nix
new file mode 100644
index 000000000000..29aaed1278d5
--- /dev/null
+++ b/pkgs/applications/graphics/megapixels/default.nix
@@ -0,0 +1,55 @@
+{ stdenv
+, lib
+, fetchgit
+, meson
+, ninja
+, pkg-config
+, wrapGAppsHook
+, gtk3
+, gnome3
+, tiffSupport ? true
+, libraw
+, jpgSupport ? true
+, imagemagick
+, exiftool
+}:
+
+assert jpgSupport -> tiffSupport;
+
+let
+  inherit (lib) makeBinPath optional optionals optionalString;
+  runtimePath = makeBinPath (
+    optional tiffSupport libraw
+    ++ optionals jpgSupport [ imagemagick exiftool ]
+  );
+in
+stdenv.mkDerivation rec {
+  pname = "megapixels";
+  version = "0.14.0";
+
+  src = fetchgit {
+    url = "https://git.sr.ht/~martijnbraam/megapixels";
+    rev = version;
+    sha256 = "136rv9sx0kgfkpqn5s90j7j4qhb8h04p14g5qhqshb89kmmsmxiw";
+  };
+
+  nativeBuildInputs = [ meson ninja pkg-config wrapGAppsHook ];
+
+  buildInputs = [ gtk3 gnome3.adwaita-icon-theme ]
+  ++ optional tiffSupport libraw
+  ++ optional jpgSupport imagemagick;
+
+  preFixup = optionalString (tiffSupport || jpgSupport) ''
+    gappsWrapperArgs+=(
+      --prefix PATH : ${runtimePath}
+    )
+  '';
+
+  meta = with lib; {
+    description = "GTK3 camera application using raw v4l2 and media-requests";
+    homepage = "https://sr.ht/~martijnbraam/Megapixels";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ OPNA2608 ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 0d19db7332c4..3647abca381a 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -23120,6 +23120,8 @@ in
 
   mediathekview = callPackage ../applications/video/mediathekview { };
 
+  megapixels = callPackage ../applications/graphics/megapixels { };
+
   meteo = callPackage ../applications/networking/weather/meteo { };
 
   meld = callPackage ../applications/version-management/meld { };