From 15c76d17fec5da6591ebdcf2eddf1eb20097ecd1 Mon Sep 17 00:00:00 2001
From: Jaka Hudoklin <jakahudoklin@gmail.com>
Date: Mon, 16 Nov 2015 15:25:14 +0100
Subject: [PATCH 1/2] heapster: init at
 3057a2c07061c8d9ffaf77e5442ffd7512ac0133

---
 pkgs/servers/monitoring/heapster/default.nix | 27 ++++++++++++++++++++
 pkgs/top-level/all-packages.nix              |  2 ++
 2 files changed, 29 insertions(+)
 create mode 100644 pkgs/servers/monitoring/heapster/default.nix

diff --git a/pkgs/servers/monitoring/heapster/default.nix b/pkgs/servers/monitoring/heapster/default.nix
new file mode 100644
index 000000000000..b5f33dff5286
--- /dev/null
+++ b/pkgs/servers/monitoring/heapster/default.nix
@@ -0,0 +1,27 @@
+{ lib, goPackages, fetchFromGitHub, docker }:
+
+goPackages.buildGoPackage rec {
+  rev = "3057a2c07061c8d9ffaf77e5442ffd7512ac0133";
+  name = "heapster-${lib.strings.substring 0 7 rev}";
+  goPackagePath = "k8s.io/heapster";
+  subPackages = [ "./" ];
+
+  src = fetchFromGitHub {
+    inherit rev;
+    owner = "kubernetes";
+    repo = "heapster";
+    sha256 = "057z9imgd2gvcbvahja3i26jzgm33dmfaxraakmcr4a2xfhj50hq";
+  };
+
+  preBuild = ''
+    export GOPATH=$GOPATH:$NIX_BUILD_TOP/go/src/${goPackagePath}/Godeps/_workspace
+  '';
+
+  meta = with lib; {
+    description = "Compute Resource Usage Analysis and Monitoring of Container Clusters";
+    license = licenses.asl20;
+    homepage = https://github.com/kubernetes/heapster;
+    maintainers = with maintainers; [ offline ];
+    platforms = with platforms; docker.meta.platforms;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 66382269ebaa..ea68679aedd9 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -9146,6 +9146,8 @@ let
 
   groovebasin = callPackage ../applications/audio/groovebasin { };
 
+  heapster = (callPackage ../servers/monitoring/heapster { }).bin // { outputs = ["bin"]; };
+
   hbase = callPackage ../servers/hbase {};
 
   ircdHybrid = callPackage ../servers/irc/ircd-hybrid { };

From aa4bad4c178c40976836aa0c9066c47dd6885418 Mon Sep 17 00:00:00 2001
From: Jaka Hudoklin <jakahudoklin@gmail.com>
Date: Mon, 16 Nov 2015 15:26:07 +0100
Subject: [PATCH 2/2] heapster module: init

---
 nixos/modules/misc/ids.nix                    |  1 +
 nixos/modules/module-list.nix                 |  1 +
 .../modules/services/monitoring/heapster.nix  | 57 +++++++++++++++++++
 3 files changed, 59 insertions(+)
 create mode 100644 nixos/modules/services/monitoring/heapster.nix

diff --git a/nixos/modules/misc/ids.nix b/nixos/modules/misc/ids.nix
index de9a318fdd24..b1130c2b124b 100644
--- a/nixos/modules/misc/ids.nix
+++ b/nixos/modules/misc/ids.nix
@@ -235,6 +235,7 @@
       kibana = 211;
       xtreemfs = 212;
       calibre-server = 213;
+      heapster = 214;
 
       # When adding a uid, make sure it doesn't match an existing gid. And don't use uids above 399!
 
diff --git a/nixos/modules/module-list.nix b/nixos/modules/module-list.nix
index 034ea933a7db..6c219575bf04 100644
--- a/nixos/modules/module-list.nix
+++ b/nixos/modules/module-list.nix
@@ -238,6 +238,7 @@
   ./services/monitoring/dd-agent.nix
   ./services/monitoring/grafana.nix
   ./services/monitoring/graphite.nix
+  ./services/monitoring/heapster.nix
   ./services/monitoring/monit.nix
   ./services/monitoring/munin.nix
   ./services/monitoring/nagios.nix
diff --git a/nixos/modules/services/monitoring/heapster.nix b/nixos/modules/services/monitoring/heapster.nix
new file mode 100644
index 000000000000..74b8c9ccd3ed
--- /dev/null
+++ b/nixos/modules/services/monitoring/heapster.nix
@@ -0,0 +1,57 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  cfg = config.services.heapster;
+in {
+  options.services.heapster = {
+    enable = mkOption {
+      description = "Whether to enable heapster monitoring";
+      default = false;
+      type = types.bool;
+    };
+
+    source = mkOption {
+      description = "Heapster metric source";
+      example = "kubernetes:https://kubernetes.default";
+      type = types.string;
+    };
+
+    sink = mkOption {
+      description = "Heapster metic sink";
+      example = "influxdb:http://localhost:8086";
+      type = types.string;
+    };
+
+    extraOpts = mkOption {
+      description = "Heapster extra options";
+      default = "";
+      type = types.string;
+    };
+
+    package = mkOption {
+      description = "Package to use by heapster";
+      default = pkgs.heapster;
+      type = types.package;
+    };
+  };
+
+  config = mkIf cfg.enable {
+    systemd.services.heapster = {
+      wantedBy = ["multi-user.target"];
+      after = ["cadvisor.service" "kube-apiserver.service"];
+
+      serviceConfig = {
+        ExecStart = "${cfg.package}/bin/heapster --source=${cfg.source} --sink=${cfg.sink} ${cfg.extraOpts}";
+        User = "heapster";
+      };
+    };
+
+    users.extraUsers = singleton {
+      name = "heapster";
+      uid = config.ids.uids.heapster;
+      description = "Heapster user";
+    };
+  };
+}